3

私は latexmk を使用して、GNU Emacs + AUCTeX 経由で .tex ドキュメントをコンパイルします (私の設定は、こちらのソリューション セクションで説明されています: Emacs + Synctex + Skim: 同期を正しく設定する方法は? [既存の方法はどれも適切に機能しませんでした] )

を使用するC-c C-cと、.tex ドキュメントがコンパイルされます (たとえば、pdflatex を使用)。このプロセスの出力は、 で表示/確認できますC-c C-l。通常、多くの出力があり、読むのが困難です。この出力を色付けする方法はありますか? 端末から latexmk を使用すると、少なくとも latexmk 出力の重要な部分が強調表示されます。

4

1 に答える 1

2

これを行う通常の方法は、メジャー モードにフォント ロック キーワードを追加することですが、出力ファイルは基本モードであるため、おそらく以下のような単純なメジャー モードを記述してからdefine-derived-mode、それを有効にするようにアドバイス (たとえばC-c C-l) することをお勧めします。モードをオンにします（アドバイスするより良い機能が確かにありますが、どれかはわかりません）。

(define-derived-mode latex-output-mode fundamental-mode "LaTeX Output"
  "Simple mode for colorizing LaTeX output."
  (set (make-local-variable 'font-lock-defaults)
       '((("^!.*" . font-lock-warning-face) ; LaTeX error
          ("^-+$" . font-lock-builtin-face) ; latexmk divider
          ("^\\(?:Overfull\\|Underfull\\|Tight\\|Loose\\).*" . font-lock-string-face)
          ;; ..... 
          ))))
(defadvice TeX-recenter-output-buffer (after colorize-latex-output activate)
  (latex-output-mode))

または、(NN が示唆するように) 上書きTeX-parse-errorして、関心のある部分を強調表示するテキスト プロパティまたはオーバーレイを追加することもできます。TeX-parse-errorこれには、 が更新された場合、バージョンも手動で更新する必要があるという欠点がありますが、それ以外の場合は作業が少なくなる可能性があります。もちろん、エラー、警告、オーバーフル/アンダーフル ボックス、ファイル情報など、ハイライトしたいものを既に検索している場合にのみ機能します。

2 番目のオプションの例は次のとおりです。

(defun TeX-parse-error (old)
  "Goto next error.  Pop to OLD buffer if no more errors are found.
This version colorizes file name parsing helping to track down annoying bugs"
  (let ((regexp
         (concat
          ;; TeX error
          "^\\(!\\|\\(.*?\\):[0-9]+:\\) \\|"
          ;; New file
          "(\\(\"[^\"]*?\"\\|/*\
\\(?:\\.+[^()\r\n{} \\/]*\\|[^()\r\n{} .\\/]+\
\\(?: [^()\r\n{} .\\/]+\\)*\\(?:\\.[-0-9a-zA-Z_.]*\\)?\\)\
\\(?:[\\/]+\\(?:\\.+[^()\r\n{} \\/]*\\|[^()\r\n{} .\\/]+\
\\(?: [^()\r\n{} .\\/]+\\)*\\(?:\\.[-0-9a-zA-Z_.]*\\)?\\)?\\)*\\)\
)*\\(?: \\|\r?$\\)\\|"
          ;; End of file
          "\\()\\))*\\|"
          ;; Hook to change line numbers
          " !\\(?:offset(\\([---0-9]+\\))\\|"
          ;; Hook to change file name
          "name(\\([^)]+\\))\\)\\|"
          ;; LaTeX bad box
          "^\\(\\(?:Overfull\\|Underfull\\|Tight\\|Loose\\)\
 \\\\.*?[0-9]+--[0-9]+\\)\\|"
          ;; LaTeX warning
          "^\\(LaTeX [A-Za-z]*\\|Package [A-Za-z]+ \\)Warning:.*")))
    (while
        (cond
         ;; Nothing found
         ((null
           (re-search-forward regexp nil t))
          ;; No more errors.
          (message "No more errors.")
          (beep)
          (TeX-pop-to-buffer old)
          nil)

         ;; TeX error
         ((match-beginning 1)
          (put-text-property (match-beginning 2) (match-end 2)
                             'face 'font-lock-warning-face)
          (when (match-beginning 2)
            (unless TeX-error-file
              (push nil TeX-error-file)
              (push nil TeX-error-offset))
            (unless (car TeX-error-offset)
              (rplaca TeX-error-file (TeX-match-buffer 2))))
          (if (looking-at "Preview ")
              t
            (TeX-error)
            nil))

         ;; LaTeX bad box
         ((match-beginning 7)
          (put-text-property (match-beginning 0) (match-end 0)
                             'face 'font-lock-doc-face)
          (if TeX-debug-bad-boxes
              (progn
                (TeX-warning (TeX-match-buffer 7))
                nil)
            (re-search-forward "\r?\n\
\\(?:.\\{79\\}\r?\n\
\\)*.*\r?$")
            t))

         ;; LaTeX warning
         ((match-beginning 8)
          (put-text-property (match-beginning 0) (match-end 0)
                             'face 'font-lock-string-face)
          (if TeX-debug-warnings
              (progn
                (TeX-warning (TeX-match-buffer 8))
                nil)
            t))

         ;; New file -- Push on stack
         ((match-beginning 3)
          (let ((file (TeX-match-buffer 3))
                (end (match-end 3)))
            (put-text-property (match-beginning 0) (match-end 0)
                               'face 'font-lock-type-face)
            ;; Strip quotation marks and remove newlines if necessary
            (when (or (eq (string-to-char file) ?\")
                      (string-match "\n" file))
              (setq file
                    (mapconcat 'identity (split-string file "[\"\n]+") "")))
            (push file TeX-error-file)
            (push nil TeX-error-offset)
            (goto-char end))
          t)

         ;; End of file -- Pop from stack
         ((match-beginning 4)
          ;; (overlay-put
          ;;  (make-overlay (match-beginning 4) (match-end 4))
          ;;  'face 'font-lock-warning-face)
          (put-text-property (match-beginning 0) (match-end 0)
                             'face 'font-lock-warning-face)
          (when (> (length TeX-error-file) 1)
            (when (string= (pop TeX-error-file) "./auctex-bug.tex")
              (goto-char (match-end 4)))
            (pop TeX-error-offset))
          (goto-char (match-end 4))
          t)

         ;; Hook to change line numbers
         ((match-beginning 5)
          (setq TeX-error-offset
                (list (string-to-number (TeX-match-buffer 5))))
          t)

         ;; Hook to change file name
         ((match-beginning 6)
          (setq TeX-error-file
                (list (TeX-match-buffer 6)))
          t)))))
于 2011-11-02T19:12:38.193 に答える