1

以下のようなxmlがあります

<rnp xmsns="v1">
  <ele1 line="1">
    <ele2></ele2>
  </ele1>
</rnp>

に変更したい

<rnp xmsns="v2">
  <ele1 line="1">
    <ele2></ele2>
  </ele1>
</rnp>

xslt 1.0 を使用します。

以下のxslを使用しています。

<?xml version="1.0" encoding="iso-8859-1"?>

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns="v2">
    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|*|node()"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="rnp">
        <rnp>
            <xsl:apply-templates select="*"/>
        </rnp>
    </xsl:template> 
</xsl:stylesheet>

ただし、この xsl は属性をコピーしないため、line 属性は出力に生成されません。

サンプル出力

<?xml version="1.0" encoding="UTF-8"?><rnp xmlns="v2"><ele1>1
        <ele2/>
      </ele1></rnp>

xsltを使用してxmlns属性のテキストのみを変更するにはどうすればよいですか? xslt を使用して xmlns を変更する他の方法はありますか? xslt 1.0 のオプションしかありません。

ありがとう。

4

2 に答える 2

3

この変換：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pNS" select="'v2'"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*[true()]">
  <xsl:element name="{local-name()}" namespace="{$pNS}">
       <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

提供されたXMLドキュメントに適用された場合（名前空間に含まれるように修正されました"v1"：

<rnp xmlns="v1">
  <ele1 line="1">
    <ele2></ele2>
  </ele1>
</rnp>

必要な正しい結果を生成します：

<rnp xmlns="v2">
   <ele1 line="1">
      <ele2/>
   </ele1>
</rnp>

注意してください：

  1. 目的の新しいデフォルトの名前空間は、外部パラメーターとして変換に渡されます。したがって、デフォルトの名前空間を変更する必要がある場合は、変更なしのsmae変換を使用できます。

  2. この変わった外観のテンプレートの一致： XSLTプロセッサの「回復可能なあいまいさエラー」メッセージを、優先度を指定するよりも短く、エレガントに<xsl:template match="*[true()]">コーディングした場合に回避できます。<xsl:template match="*">

于 2011-11-07T13:50:44.367 に答える
0 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                xmlns="v2">
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@* | node()"/>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

出力：

<rnp xmlns="v2">
    <ele1 line="1">
        <ele2 />
    </ele1>
</rnp>
于 2011-11-07T12:00:42.897 に答える