注：この機能を備えた既製のパレットをここで入手してください。
Arnoudのソリューションは私を興奮させ、焦りました。それで、これが改善されました。私は彼のコードを研究せずにこれを行うことはできませんでした。このバージョンの方が信頼性が高く、タイムアウトエラーが発生しにくいようですが、正直なところ、Javaはまったく知らないので、改善を歓迎します。
最も重要なこと：このバージョンはにstack.imgur.com直接アップロードされるため、アップロードされた画像がしばらくすると消えることを心配することなく、ここStackOverflowで安全に使用できます。
私は3つの機能を提供します：
stackImage式をアップロードし、PNGとしてエクスポートして、URLを返しますstackMarkdownコピーの準備ができて、マークダウンを返しますstackCopyMarkdownマークダウンをクリップボードにコピーします
次のステップ：ノートブックで選択したグラフィックに対してこれを自動的に行うパレットボタンを作成します。コードの改善は大歓迎です。
Needs["JLink`"]
stackImage::httperr = "Server returned respose code: `1`";
stackImage::err = "Server returner error: `1`";
stackImage[g_] :=
Module[
{getVal, url, client, method, data, partSource, part, entity, code,
response, error, result},
(* this function attempts to parse the response fro the SO server *)
getVal[res_, key_String] :=
With[{k = "var " <> key <> " = "},
StringTrim[
First@StringCases[First@Select[res, StringMatchQ[#, k ~~ ___] &],
k ~~ v___ ~~ ";" :> v],
"'"]
];
data = ExportString[g, "PNG"];
JavaBlock[
url = "https://stackoverflow.com/upload/image";
client = JavaNew["org.apache.commons.httpclient.HttpClient"];
method = JavaNew["org.apache.commons.httpclient.methods.PostMethod", url];
partSource = JavaNew["org.apache.commons.httpclient.methods.multipart.ByteArrayPartSource", "mmagraphics.png", MakeJavaObject[data]@toCharArray[]];
part = JavaNew["org.apache.commons.httpclient.methods.multipart.FilePart", "name", partSource];
part@setContentType["image/png"];
entity = JavaNew["org.apache.commons.httpclient.methods.multipart.MultipartRequestEntity", {part}, method@getParams[]];
method@setRequestEntity[entity];
code = client@executeMethod[method];
response = method@getResponseBodyAsString[];
]
If[code =!= 200, Message[stackImage::httperr, code]; Return[$Failed]];
response = StringTrim /@ StringSplit[response, "\n"];
error = getVal[response, "error"];
result = getVal[response, "result"];
If[StringMatchQ[result, "http*"],
result,
Message[stackImage::err, error]; $Failed]
]
stackMarkdown[g_] := "![Mathematica graphics](" <> stackImage[g] <> ")"
stackCopyMarkdown[g_] := Module[{nb, markdown},
markdown = Check[stackMarkdown[g], $Failed];
If[markdown =!= $Failed,
nb = NotebookCreate[Visible -> False];
NotebookWrite[nb, Cell[markdown, "Text"]];
SelectionMove[nb, All, Notebook];
FrontEndTokenExecute[nb, "Copy"];
NotebookClose[nb];
]
]
アップデート：
これは、選択範囲のプレビューを表示し、アップロード（またはキャンセル）を提供するボタンです。以前の関数を定義する必要があります。
Button["Upload to SO",
Module[{cell = NotebookRead@InputNotebook[], img},
If[cell =!= {}, img = Rasterize[cell];
MessageDialog[
Column[{"Upload image to StackExchange sites?",
img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img],
"Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]]]]
残念ながらCreatePalette、パレットの寸法がラスタライズに影響するため、ボタンをパレット（）に配置できません。この問題の解決策は大歓迎です。
アップデート2：
この質問への回答に基づいて、Windows専用のパレットボタンが機能します。
button = Button["Upload to SO",
Module[{sel},
FrontEndExecute[
FrontEndToken[FrontEnd`SelectedNotebook[], "CopySpecial", "MGF"]];
sel = Cases[NotebookGet@ClipboardNotebook[],
RasterBox[data_, ___] :>
Image[data, "Byte", ColorSpace -> "RGB", Magnification -> 1],
Infinity];
If[sel =!= {},
With[{img = First[sel]},
MessageDialog[
Column[{"Upload image to StackExchange sites?",
img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img],
"Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]
]
]
]
]
CreatePalette[button]
警告：プレビューボックスで[キャンセル]をクリックしても、クリップボードの内容は破棄されます。
