3


サーバーは ActiveState Perl を実行している Windows XP 上にありますサーバー
は内部ネットワークと外部ネットワークに接続されています 内部ネットワーク上
のコンピュータはポート 9722 で 10.4.255.255 に udp でブロードキャストしています


ブロードキャストをリッスンし、メッセージを関数に渡す必要があります

これは私が使用しているコードです:


my $sock;

do {
  eval {
    $sock = IO::Socket::INET->new(LocalPort => 9722, Proto => 'udp')
            or die("Couldn't open the socket: $@");
    1;
  };
  warn($@) and sleep(5) if($@);
} while ($@);

for(my $i = 0;$i < 20;$i++) {
  my $string = 'a';
  $sock->recv($string,1024);
  print &parseInput($string);
}

&parseInput は、渡された元の文字列を返すことに注意してください。

私の問題:
$sock->recv() を呼び出した後、$string が空になります。別のアプリケーションを使用すると、間違いなく 10.4.255.255 で情報がブロードキャストされていることがわかりますが、アクセスできません。
できれば、IO::Socket::INET を使い続けたいと思っています。

編集: recv(..) と $! の戻り値を確認しました。recv(..) と $! からの戻り値はありません。= 「不明なエラー」。

編集 2: Socket を使用しようとしています。今、次のものがあります：


$proto = getprotobyname('udp');
socket(SOCKET, PF_INET, SOCK_DGRAM, $proto) or die "socket: $!";
setsockopt(SOCKET, SOL_SOCKET, SO_BROADCAST, 1) or die "sockopt: $!";
bind(SOCKET, sockaddr_in(9722, inet_aton('192.168.0.103'))) or die "bind: $!";
recv(SOCKET, $msg, 128, 0) or die "recv: $!";


エラーが生成されます -- recv: Unknown error at ...

4

2 に答える 2

4

あなたが主な問題であることがわかったと思います。

受信者は、任意のインターフェイス ( INADDR_ANY ) またはネットワークのブロードキャスト アドレス (すべてのネットワーク 1 または指定されたもの) のいずれかにバインドする必要があります。

ブロードキャストの送信者と受信者の両方のコード例を次に示します。

setsockopt を使用するときは注意してください。最後の引数をパックする必要があります。

#!/usr/bin/perl -w
# broadcast sender script
use strict;
use diagnostics;
use Socket;

my $sock;
my $receiverPort = 9722;
my $senderPort = 9721;

socket($sock, PF_INET, SOCK_DGRAM, getprotobyname('udp'))   || die "socket: $!";
setsockopt($sock, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))   || die "setsockopt: $!";
setsockopt($sock, SOL_SOCKET, SO_BROADCAST, pack("l", 1)) or die "sockopt: $!";
bind($sock, sockaddr_in($senderPort, inet_aton('192.168.2.103')))  || die "bind: $!";

while (1) {
    my $datastring = `date`;
    my $bytes = send($sock, $datastring, 0, 
                     sockaddr_in($receiverPort, inet_aton('192.168.2.255')));
    if (!defined($bytes)) { 
        print("$!\n"); 
    } else { 
        print("sent $bytes bytes\n"); 
    }
    sleep(2);
}

#!/usr/bin/perl -w
# broadcast receiver script
use strict;
use diagnostics;
use Socket;

my $sock;

socket($sock, PF_INET, SOCK_DGRAM, getprotobyname('udp'))   || die "socket: $!";
setsockopt($sock, SOL_SOCKET, SO_REUSEADDR, pack("l", 1))   || die "setsockopt: $!";
bind($sock, sockaddr_in(9722, inet_aton('192.168.2.255')))  || die "bind: $!"; 

# just loop forever listening for packets
while (1) {
    my $datastring = '';
    my $hispaddr = recv($sock, $datastring, 64, 0); # blocking recv
    if (!defined($hispaddr)) {
        print("recv failed: $!\n");
        next;
    }
    print "$datastring";
}
于 2009-05-07T12:49:03.257 に答える
1

$sock->recv、およびの戻り値を確認しますprint "$!\n"。$string空になるとどのようなエラーメッセージが出力されますか? を呼び出す前に$sock->connect(...)またはを実行する必要がある場合があります。$sock->bind(...)$sock->recv()

于 2009-05-01T22:07:14.710 に答える