これを実現するためのカスタム制約を作成できます。次の 3 つのスクリプトを使用してこれを行うことに成功しました。
- セットアップ db.xqy
- 検索.xqy
- カスタム制約.xqy
2 つの "Amount" 範囲インデックスを作成し、いくつかのサンプル ドキュメント (test1.xml と test2.xml) を追加するセットアップ スクリプトを次に示します。
xquery version "1.0-ml";
import module namespace admin = "http://marklogic.com/xdmp/admin" at "/MarkLogic/admin.xqy" ;
declare namespace TM360 = "http://example.com/TM360";
declare namespace Measurements = "http://example.com/Measurements";
declare function local:make-amount-index($parent-name) {
admin:database-range-element-attribute-index(
(: data type :) "decimal",
(: parent name :) "http://example.com/Measurements",$parent-name,
(: attribute name :) "", "Amount",
(: collation :) "",
(: value positions :) false()
)
};
(: Set up the indexes (or you can add these via the Admin UI) :)
let $dbid := xdmp:database(),
$rangespec1 := local:make-amount-index("Distance"),
$rangespec2 := local:make-amount-index("Volume"),
$config := admin:get-configuration(),
$config := admin:database-add-range-element-attribute-index($config, $dbid, $rangespec1),
$config := admin:database-add-range-element-attribute-index($config, $dbid, $rangespec2)
return
admin:save-configuration($config)
,
(: Add some sample docs :)
xdmp:document-insert("/test1.xml",
<TM360:Measurements Measurements="Distance">
<Measurements:Distance Amount="3" Unit="inches"/>
</TM360:Measurements>),
xdmp:document-insert("/test2.xml",
<TM360:Measurements Measurements="Volume">
<Measurements:Volume Amount="5.0" Unit="liters"/>
</TM360:Measurements>)
以下は、2 つの検索を行う search.xqy です。
search:search("Amount:3",$options)search:search("Amount:5",$options)
特に、カスタム制約を定義する $options ノードに注意してください。
xquery version "1.0-ml";
import module namespace search="http://marklogic.com/appservices/search"
at "/MarkLogic/appservices/search/search.xqy";
declare variable $options :=
<options xmlns="http://marklogic.com/appservices/search">
<constraint name="Amount">
<custom facet="false">
<parse apply="parse-amount"
ns="http://example.com/custom-constraint"
at="/custom-constraint/custom-constraint.xqy">
</parse>
</custom>
</constraint>
</options>;
(: matches test1.xml :)
search:search("Amount:3",$options),
(: matches test2.xml :)
search:search("Amount:5",$options)
最後に、custom-constraint.xqy コードを示します。これは、制約テキストを 2 つの Amount インデックスにわたる cts OR クエリに変換するものです。
xquery version "1.0-ml";
module namespace my = "http://example.com/custom-constraint";
declare namespace Measurements = "http://example.com/Measurements";
declare default function namespace "http://www.w3.org/2005/xpath-functions";
(: Convert the constraint text into an OR query against "Distance" and "Volume" :)
declare function my:parse-amount($constraint-qtext as xs:string,
$right as schema-element(cts:query))
as schema-element(cts:query)
{
let $value := xs:decimal($right//cts:text)
return
<cts:or-query>{
my:make-amount-query("Distance",$value),
my:make-amount-query("Volume" ,$value)
}</cts:or-query>
};
declare function my:make-amount-query($parent-name, $value) {
cts:element-attribute-range-query(
(: parent name :) QName("http://example.com/Measurements", $parent-name),
(: attribute name :) xs:QName("Amount"),
(: operator :) "=",
(: value :) $value
)
};
制約をファセットとしても機能させたい場合は、さらに start-facet 関数と finish-facet 関数を実装する必要があります (それに応じて、オプション ノードの定義を拡張します。検索開発者ガイドには、方法の例が含まれています。これを行う。