1

< mx:Text > コンポーネントの上を移動しているときに、カーソル/マウスが上にある単語を見つけることは可能ですか? たとえば、ユーザーが文に沿ってマウスを移動すると (テキスト コンポーネント内)、各単語が強調表示されます (マウス ボタンを押しながら強調表示できることはわかっていますが、それは私が望む方法ではありません)。

情報をありがとう。

4

2 に答える 2

2

これを行う1つの方法は、mx：Textコンポーネントを拡張する独自のコンポーネントを作成する必要があるということです。MyTextこの例で使用しました。完全なコードは次のMyTextとおりです。

<?xml version="1.0" encoding="utf-8"?>
<mx:Text xmlns:mx="http://www.adobe.com/2006/mxml" mouseMove="onMouseMove(event)" initialize="init()">
    <mx:Script>
        <![CDATA[

            // Text formats
            private var normalTextFormat:TextFormat;
            private var highlightTextFormat:TextFormat;

            // Saved word start and end indexes
            private var wordStartIndex:int = -1;
            private var wordEndIndex:int = -1;

            private function init():void
            {
                normalTextFormat = textField.getTextFormat();
                normalTextFormat.color = 0;
                highlightTextFormat = textField.getTextFormat();
                highlightTextFormat.color = 0xFF0000;
            }

            private function onMouseMove(event:MouseEvent):void
            {
                // Clear previous word highlight
                textField.setTextFormat(normalTextFormat, wordStartIndex, wordEndIndex);

                var charIndexUnderMouse:int = textField.getCharIndexAtPoint(event.localX, event.localY);
                wordStartIndex = charIndexUnderMouse;
                wordEndIndex = charIndexUnderMouse;

                // Find start of word
                while (text.charAt(wordStartIndex) != " " && wordStartIndex > 0)
                {
                    wordStartIndex--;
                }

                // Find end of word
                while (text.charAt(wordEndIndex) != " " && wordEndIndex < text.length)
                {
                    wordEndIndex++;
                }

                // Highlight character
                textField.setTextFormat(highlightTextFormat, wordStartIndex, wordEndIndex);
            }
        ]]>
    </mx:Script>

</mx:Text>

これは、Textコンポーネント内のTextFieldオブジェクトのメソッドにアクセスし、マウス座標の下で文字インデックスを見つけてから、その文字が属する単語を見つけることによって機能します。これは簡単な例です。実際に使用するには、おそらくもっと複雑にする必要があります。

于 2009-05-02T13:26:26.157 に答える
0

TextSnapshot クラスを使用する必要があります。textSnapshot プロパティからテキスト コントロールから取得できます。TextSnapshot には、hitTestTextNearPos() 関数があり、ユーザーのマウスがどの文字に近づいているかを判断するために使用できます。

...
var startIndex:Number;
...

private function textMouseMoveHandler(event:MouseEvent):void
{
    var snapshot:TextSnapshot = text.textSnapshot;
    var index = snapshot.hitTestTextNearPos(event.x, event.y);

    snapshot.setSelected(startIndex, index, true);
}

// I do not know how you want to begin the selection, so I put it here in the MouseEnter event.
private function textMouseEnterHandler(event:MouseEvent):void
{

    var snapshot:TextSnapshot = text.textSnapshot;
    startIndex = snapshot.hitTestTextNearPos(event.x, event.y);
}

選択の開始をどのように処理したいかはわかりませんが、そのようなものは機能するはずです。

于 2009-05-01T15:19:25.113 に答える