192

私は次の機能を使用します

=DAYS360(A2, A35)

私の列の2つの日付の差を計算します。ただし、列は拡大し続けており、現在、スプレッドシートを更新するときに「A35」を手動で変更する必要があります。

（Googleスプレッドシートで）この列の最後の空でないセルを見つけて、上記の関数でそのパラメーターを動的に設定する方法はありますか？

4

19 に答える 19

224

もっと雄弁な方法があるかもしれませんが、これは私が思いついた方法です：

列の最後に入力されたセルを検索する関数は次のとおりです。

=INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) )

したがって、現在の関数と組み合わせると、次のようになります。

=DAYS360(A2,INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) ))
于 2011-11-17T01:54:39.530 に答える
96

空でない最後のセルを見つけるには、次のようINDEXに使用できます。MATCH

=DAYS360(A2; INDEX(A:A; MATCH(99^99;A:A; 1)))

これは少し速くて簡単だと思います。

于 2014-09-09T08:13:20.490 に答える
67

A2：Aに連続して日付が含まれている場合、INDEX（A2：A、COUNT（A2：A））は最後の日付を返します。最終的な式は

=DAYS360(A2,INDEX(A2:A,COUNT(A2:A)))
于 2016-03-25T22:37:30.613 に答える
48

私のお気に入りは：

=INDEX(A2:A,COUNTA(A2:A),1)

したがって、OPの必要性のために：

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))
于 2017-03-31T13:09:44.147 に答える
42

質問はすでに答えられていますが、それを行うための雄弁な方法があります。

Use just the column name to denote last non-empty row of that column.

例えば：

データが入っA1:A100ていて、列Aにさらにデータを追加できるようにしたい場合A1:A105は、次のA1:A1234範囲を使用できます。

A1:A

サンプル

したがって、範囲内の最後の空でない値を取得するには、次の2つの関数を使用します。

  • COUNTA
  • 索引

答えは=INDEX(B3:B,COUNTA(B3:B))です。

説明は次のとおりです。

COUNTA(range)範囲内の値の数を返します。これを使用して行数を取得できます。

INDEX(range, row, col)row位置およびcol（col=1指定されていない場合）の範囲の値を返します

例：

INDEX(A1:C5,1,1) = A1
INDEX(A1:C5,1) = A1 # implicitly states that col = 1
INDEX(A1:C5,1,2) = A2
INDEX(A1:C5,2,1) = B1
INDEX(A1:C5,2,2) = B2
INDEX(A1:C5,3,1) = C1
INDEX(A1:C5,3,2) = C2

上の写真の場合、範囲はになりますB3:B。B3:Bしたがって、COUNTA(B3:B)最初に範囲内にある値の数を数えます。左側8では8つの値があるため生成されます9が、右側では生成されます。また、最後の値が範囲の最初の列にあることもわかっているB3:Bため、のcolパラメーターはINDEX1で、rowパラメーターはである必要がありますCOUNTA(B3:B)。

PS：@bloodymurderliveが最初に書いたので、答えに賛成してください。ここで説明します。

于 2017-01-24T22:44:29.303 に答える
19

私の場合のように、列が連続して追加された日付によってのみ拡張された場合、MAX関数のみを使用して最終日付を取得しました。

最終的な式は次のようになります。

=DAYS360(A2; MAX(A2:A))
于 2016-08-01T23:01:26.570 に答える
13

もう1つあります：

=indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),""))))

最終的な方程式は次のとおりです。

=DAYS360(A2,indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),"")))))

ここにある他の方程式は機能しますが、行番号を簡単に取得できるので、これが好きです。これは、もっと頻繁に行う必要があると思います。行番号は次のようになります。

=max(arrayformula(if(A:A<>"",row(A:A),"")))

私はもともとスプレッドシートの問題を解決するためにこれだけを見つけようとしましたが、最後のエントリの行番号を示すだけの有用なものは見つからなかったので、これが誰かに役立つことを願っています。

また、これには、任意のタイプのデータに対して任意の順序で機能し、コンテンツを含む行の間に空白行を含めることができ、「」と評価される数式を含むセルをカウントしないという追加の利点があります。繰り返される値も処理できます。全体として、ここでmax（（G：G <> ""）* row（G：G））を使用する式と非常に似ていますが、それが目的の場合は、行番号を少し簡単に引き出すことができます。 。

あるいは、シートにスクリプトを配置したい場合、これを頻繁に行うことを計画している場合は、自分で簡単にすることができます。これがそのスクリプトです：

function lastRow(sheet,column) {
  var ss = SpreadsheetApp.getActiveSpreadsheet();
  if (column == null) {
    if (sheet != null) {
       var sheet = ss.getSheetByName(sheet);
    } else {
      var sheet = ss.getActiveSheet();
    }
    return sheet.getLastRow();
  } else {
    var sheet = ss.getSheetByName(sheet);
    var lastRow = sheet.getLastRow();
    var array = sheet.getRange(column + 1 + ':' + column + lastRow).getValues();
    for (i=0;i<array.length;i++) {
      if (array[i] != '') {       
        var final = i + 1;
      }
    }
    if (final != null) {
      return final;
    } else {
      return 0;
    }
  }
}

現在編集しているシートと同じシートの最後の行が必要な場合は、ここに次のように入力できます。

=LASTROW()

または、そのシートの特定の列の最後の行、または別のシートの特定の列の最後の行が必要な場合は、次のように実行できます。

=LASTROW("Sheet1","A")

そして、一般的に特定のシートの最後の行について：

=LASTROW("Sheet1")

次に、実際のデータを取得するには、間接的に使用できます。

=INDIRECT("A"&LASTROW())

または、上記のスクリプトを最後の2行（実際の列から実際の値を取得するにはシートと列の両方を配置する必要があるため、最後の2行）で変更し、変数を次のように置き換えることができます。

return sheet.getRange(column + final).getValue();

と

return sheet.getRange(column + lastRow).getValue();

このスクリプトの利点の1つは、「」と評価される方程式を含めるかどうかを選択できることです。引数が追加されていない場合、「」に評価される方程式がカウントされますが、シートと列を指定すると、それらがカウントされるようになります。また、スクリプトのバリエーションを使用する場合は、多くの柔軟性があります。

おそらくやり過ぎですが、すべて可能です。

于 2018-01-12T16:08:47.737 に答える
12

これは私のために働きます。Googleスプレッドシートの列Aの最後の値を取得します。

=index(A:A,max(row(A:A)*(A:A<>"")))

（また、中間の空白行がある場合はスキップします）

于 2020-01-15T12:17:14.120 に答える
10

これは、拡大し続ける列の最後の値を取得するために私が見つけた最も簡単な解決策のようです。

=INDEX(A:A,COUNTA(A:A),1)
于 2020-01-08T01:12:58.047 に答える
6

最後の値を取得するためのこの式はどうですか？

=index(G:G;max((G:G<>"")*row(G:G)))

そして、これは元のタスクの最終的な式になります。

=DAYS360(G10;index(G:G;max((G:G<>"")*row(G:G))))

最初の日付がG10であるとします。

于 2015-04-22T20:37:50.487 に答える
5

私は別のルートに行きました。行/列に1つずつ何かを追加することがわかっているので、最初にデータがあるフィールドを数えることによって最後の行を見つけます。これをコラムで示します。

=COUNT(A5:A34)

それで、21を返したとしましょう。A5は4行下にあるので、4行目から21番目の位置を取得する必要があります。私は次のように、不正を使用してこれを行うことができます：

=INDIRECT("A"&COUNT(A5:A34)+4)

データを含む行の量を検出し、インデックス修飾子として使用している数値を返します。

于 2019-01-23T06:35:05.210 に答える
4

行の場合：

=ARRAYFORMULA(INDIRECT("A"&MAX(IF(A:A<>"", ROW(A:A), ))))

列の場合：

=ARRAYFORMULA(INDIRECT(ADDRESS(1, MAX(IF(1:1<>"", COLUMN(1:1), )), 4)))
于 2019-07-13T03:04:15.343 に答える
2

列の最後の空でないセルを厳密に見つけるには、これが機能するはずです...

=LOOKUP(2^99, A2:A)
于 2021-12-26T05:10:59.317 に答える
1

列Aの最新の日付とセルA2の日付の差を計算します。

=MAX(A2:A)-A2
于 2019-01-11T14:37:34.170 に答える
1

空でない最後の行番号を見つけるために（それらの間に空白を許可する）、以下で列を検索しAました。

=ArrayFormula(IFNA(match(2,1/(A:A<>""))))
于 2019-12-05T14:03:15.793 に答える
1

これにより、最後のセルの内容が表示されます。

=indirect("A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>""))))

これにより、最後のセルのアドレスがわかります。

="A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

これにより、最後のセルの行が表示されます。

=max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

たぶん、あなたはスクリプトを好むでしょう。このスクリプトは、他の誰かが上に投稿した巨大なスクリプトよりもはるかに短いです。

スクリプトエディタに移動し、次のスクリプトを保存します。

function getLastRow(range){
  while(range.length>0 && range[range.length-1][0]=='') range.pop();
  return range.length;
}

これが行われると、セルにこれを入力する必要があります。

=getLastRow(A:A)
于 2019-12-06T11:52:07.283 に答える
0

アマチュアのやり方は「=CONCATENATE（ "A"、COUNTUNIQUE（A1：A9999））」です。ここで、A1は列の最初のセルであり、A9999はその列のはるか下にあります。この結果のA＃は、必要に応じてINDIRECT関数で使用できます。

于 2016-05-20T21:03:03.540 に答える
0

ベンコリンズはGoogleスプレッドシートの第一人者であり、彼のサイトには無料で多くのヒントがあり、コースも提供しています。彼はダイナミックレンジ名に関する無料の記事を持っており、私はこれを私のプロジェクトの多くの基礎として使用しました。

https://www.benlcollins.com/formula-examples/dynamic-named-ranges/

免責事項、私はベンのサイトを参照することによって得るものは何もありません。

ダイナミックレンジを使用した私のプロジェクトのスクリーンショットは次のとおりです。

ここに画像の説明を入力してください

セルD3には、配列数式としての場合を除いて、上記の数式があります。

=ArrayFormula(MAX(IF(L2s!A2:A1009<>"",ROW(2:1011))))

セルD4の式は次のとおりです。

="L2s!A2:E"&D3
于 2021-04-08T21:59:04.050 に答える
0

これはうまくいくかもしれません：

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A)))

于 2021-12-15T17:57:38.300 に答える