cocoa - Cocoa-Applescript NSOpenPanel？

Question

NSOpenPanelCocoa-Applescriptでどうすればよいですか？良いチュートリアルはありますか？私はApplescriptに精通していますが、実際にはCocoaの部分ではありません。nibNSOpenPanelにはが必要ですか？Automatorアクションを実行しています。私の前の質問を参照してください。

Answer 1

ShaneStanleyのPDFブックAppleScriptObjCExploredは、AppleScriptObjCチュートリアル用に入手できるものです。Appleのほとんどすべての例は既存のObjCドキュメントにあり、変換する必要があります。

アクションのインターフェイスで使用できるAutomatorパスポップアップボタンがありますが、基本的な開いているパネルは次のようになります（独自のペン先は必要ありません）。

set defaultDirectory to POSIX path of (path to desktop) -- a place to start

tell current application's NSOpenPanel's openPanel()
    setFloatingPanel_(true)
    setTitle_("Panel Test")
    setPrompt_("Choose") -- the button name
    setMessage_("Choose some stuff:")
    setDirectoryURL_(current application's NSURL's URLWithString_(defaultDirectory))

    setCanChooseFiles_(true)
    setCanChooseDirectories_(true)
    setShowsHiddenFiles_(false)
    setTreatsFilePackagesAsDirectories_(false)
    setAllowsMultipleSelection_(true)

    set theResult to it's runModal() as integer -- show the panel
    if theResult is current application's NSFileHandlingPanelCancelButton then quit -- cancel button
    set theFiles to URLs() as list --> a list of NSURLs
end tell

AppleScriptエディタを使用している場合、エディタから直接AppleScriptObjCコードを実行することはできず、Cocoa-AppleScriptアプレットで実行する必要があることに注意してください。ただし、エディターから使用できるASObjC Runnerバックグラウンドアプリケーション（これもStanley氏による）があります。