3

OLE 検索置換を使用して、「プレースホルダー タグ」を db フィールドに保存されているコンテンツに置き換えて Word ドキュメントに入れています。ここで説明したのと同様の手法を使用します。

これは機能しますが、もちろん rtf フィールドでは機能しません。rtf データを含む db フィールドがあり、検索置換を行うと完全な rtf コードが取得されるため、表示する代わりに

ハローワールド

のようなものが見えます

{\rtf1\ansi\ansicpg1252\deff0\deflang1040 \viewkind4\uc1\pard\sa200\sl276\slmult1\lang16\b\f0\fs22 Hello \i World\b0\i0\par }

誰かがすでに問題を解決しましたか? StackOverflow で検索すると、 clipboard を使用するトリックが見つかりました。注: ブックマークは使用しません。この例ではブックマークを使用します。タグを '' のようなプレーン テキストとして定義するだけで、検索と置換のループで '' が見つかったら、テキストを置き換えます。

更新: このクリップボードのトリックに問題はありますか?

他のアイデアがあり、他の解決策を提案できますか?

4

2 に答える 2

1

代わりに Selection.InsertFile を使用することをお勧めします。これは、「プレースホルダー」を見つけてrtfファイルを挿入する例です。RTF を一時ファイルに保存してから... 

 procedure TForm1.Button1Click(Sender: TObject);
var
  Fword,FDocument,FFindObject:OleVariant;
  Filename:String;

begin
   Filename := 'C:\temp\test.doc';
   Fword := CreateOleObject('Word.Application');
   FDocument := Fword.Documents.Add(Filename);
   FFindObject := FDocument.ActiveWindow.Selection.Find;
   Fword.visible := true;
   FFindObject.ClearFormatting;
   FFindObject.Replacement.ClearFormatting;
   FFindObject.Text := 'placeholder';
   FFindObject.Forward := True;
   FFindObject.Replacement.Text := '';
   FFindObject.Wrap := 1;
   FFindObject.MatchCase := False;
   FFindObject.MatchWholeWord := False;
   FFindObject.MatchWildcards := False;
   FFindObject.MatchSoundsLike := False;
   FFindObject.MatchAllWordForms := False;

   if FFindObject.Execute() then Fword.selection.InsertFile('C:\temp\test.rtf')   
end;
于 2011-11-17T13:07:48.740 に答える
0

ずいぶん前から保存しておいた記事です。これは、TeamB の Dr. Peter Below によって古い Borland Delphi ニュースグループに投稿されましたが、今日でも適用されます。EM_STREAMINおよびEM_STREAMOUTメッセージと関連するコールバックを使用して、RTF テキストを に挿入し、 からコピーする方法を示しますTRichEdit。

Uses RichEdit;

Type
  TEditStreamCallBack = function (dwCookie: Longint; pbBuff: PByte;
    cb: Longint; var pcb: Longint): DWORD; stdcall;

  TEditStream = record
    dwCookie: Longint;
    dwError: Longint;
    pfnCallback: TEditStreamCallBack;
  end;

function EditStreamInCallback(dwCookie: Longint; pbBuff: PByte;
 cb: Longint; var pcb: Longint): DWORD; Stdcall;
var
  theStream: TStream;
  dataAvail: LongInt;
begin
  theStream := TStream(dwCookie);
  with theStream do begin
    dataAvail := Size - Position;
    Result := 0; {assume everything is ok}
    if dataAvail <= cb then begin 
      pcb := Read(pbBuff^, dataAvail); 
      if pcb <> dataAvail then  //couldn't read req. amount of bytes
        result := E_FAIL; 
    end 
    else begin
      pcb := Read(pbBuff^, cb); 
      if pcb <> cb then 
        result := E_FAIL; 
    end;
  end;
end;


Function EditStreamOutCallback(dwCookie: Longint; pbBuff: PByte;
    cb: Longint; var pcb: Longint): DWORD; stdcall;
 var
   theStream: TStream;
 begin
   theStream := TStream(dwCookie);

   with theStream do begin
     If cb > 0 Then 
       pcb := Write(pbBuff^, cb);
     Result := 0;
   end;
 end;

Procedure GetRTFSelection( aRichEdit: TRichEdit; intoStream: TStream );
Var
  editstream: TEditStream;
Begin
  With editstream Do Begin
    dwCookie:= Longint(intoStream);
    dwError:= 0;
    pfnCallback:= EditStreamOutCallBack;
  end;
  aRichedit.Perform( EM_STREAMOUT, SF_RTF or SFF_SELECTION, longint(@editstream));
End;

Procedure PutRTFSelection( aRichEdit: TRichEdit; sourceStream: TStream );
Var
  editstream: TEditStream;
Begin
  With editstream Do Begin
    dwCookie:= Longint(sourceStream);
    dwError:= 0;
    pfnCallback:= EditStreamInCallBack;
  end;
  aRichedit.Perform( EM_STREAMIN, SF_RTF or SFF_SELECTION, longint(@editstream));
End;
于 2011-11-17T14:31:43.813 に答える