1

Data::Dumperで出力したオブジェクトがあります:

$VAR1 = {
          'record' => [
                      {
                        'text' => 'booting kernel',
                        'version' => '2',
                        'iso8601' => '2011-06-23 11:57:14.250 +02:00',
                        'event' => 'system booted',
                        'modifier' => 'na'
                      },
                      {
                        'text' => 'successful login',
                        'subject' => {
                                     'sid' => '999',
                                     'uid' => 'user',
                                     'audit-uid' => 'user',
                                     'tid' => '0 0 unknown',
                                     'ruid' => 'user',
                                     'rgid' => 'gsp',
                                     'pid' => '999',
                                     'gid' => 'gsp'
                                   },
                        'version' => '2',
                        'iso8601' => '2011-06-23 11:58:00.151 +02:00',
                        'event' => 'login - local',
                        'return' => {
                                    'retval' => '0',
                                    'errval' => 'success'
                                  },
                        'host' => 'unknown'
                      },
                    ],
          'file' => {
                    'iso8601' => '2011-06-23 11:57:40.064 +02:00'
                  }
        };

そのようなハッシュをナビゲートする各値を出力したいと思います。私が理解したのは、2 つのキー (レコード、ファイル) を持つハッシュと、ハッシュの配列へのレコード ポイントです。

この構造の各値に到達するのを手伝ってもらえますか?

私は試した：

my @array=$VAR1{'record'};
foreach (@array) {
    print $_{'text'};    
}

…しかし、うまくいきません。

4

3 に答える 3

3

それを反復したいだけなら、次のようにすることができます：

iterate($VAR1);

sub iterate {
    my $input = shift;
    unless (ref $input) {
        print "$input\n";
    } elsif (ref $input eq 'ARRAY') {
        iterate($_) for @$input;
    } elsif (ref $input eq 'HASH') {
        for (keys %$input) {
            print "$_\n";
            iterate($input->{$_});
        }
    } else {
        print ref $input,"\n";
    }
}

これは、Data::Dumper のように正確に出力するわけではありませんが、よくわからない任意のネストされた構造で何か他のことをしたい場合には、この手法が役立つかもしれません。

于 2011-11-23T21:14:15.147 に答える
1

$VAR1{record}配列ではなく、配列参照です。配列にアクセスするには、逆参照する必要があります。

my @array = @{ $VAR1->{record} };

配列内の各要素はハッシュ参照であるため、次のようになります。

for my $record ( @array ) {
    print $record->{text};
}
于 2011-11-23T17:10:30.410 に答える
0

$VAR1参考です。逆参照する必要があります。 $VAR1->{record}参考です。あなたもそれを逆参照する必要があります。 $_も参照であるため、それを逆参照する必要があります。

perldoc perlreftut

my @array = @{ $VAR1->{'record'} };
foreach (@array) { 
    print $_->{'text'}; 
}
于 2011-11-23T17:14:53.707 に答える