2

各文字にリンクを付けてアルファベットを書きたいと思います。だから私はテンプレートを使用しましたが、この文字を作成する方法がわかりません.

<xsl:template name="alphabet">
    <xsl:param name="iLetter"/>
    <xsl:if test="$iLetter &lt; 91">
        <a><xsl:attribute name="href">req.html?X_letter=&#<xsl:value-of select="$iLetter"/>;</xsl:attribute>&#<xsl:value-of select="$iLetter"/>;</xsl:attribute></a>
        <xsl:call-template name="alphabet">
            <xsl:with-param name="iLetter" select="number($iLetter)+1"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

そして、私はこのテンプレートを次のように呼んでいます:

<xsl:call-template name="alphabet">
        <xsl:with-param name="iLetter" select="number(65)"/>
</xsl:call-template>

だから、私はこの結果を得たいと思います：

A B C D ..... X Y Zせずに...もちろん:)

4

4 に答える 4

2

aどの要素のテキストの子も正しく生成されないため、現在受け入れられている回答は正しくありません。

正しい XSLT 1.0 ソリューションは次のとおりです。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vAlpha" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

 <xsl:template match="/">
     <xsl:call-template name="alphabet"/>
 </xsl:template>

 <xsl:template name="alphabet">
  <xsl:param name="pCode" select="65"/>
  <xsl:if test="not($pCode > 90)">
    <xsl:variable name="vChar" select=
     "substring($vAlpha, $pCode - 64, 1)"/>
    <a href="req.html?X_letter={$vChar}">
     <xsl:value-of select="$vChar"/>
    </a>
    <xsl:call-template name="alphabet">
      <xsl:with-param name="pCode" select="$pCode+1"/>
    </xsl:call-template>
   </xsl:if>
 </xsl:template>
</xsl:stylesheet>

任意の XML ドキュメント (使用されていない) に適用すると、必要な正しい結果が生成されます。

<a href="req.html?X_letter=A">A</a>
<a href="req.html?X_letter=B">B</a>
<a href="req.html?X_letter=C">C</a>
<a href="req.html?X_letter=D">D</a>
<a href="req.html?X_letter=E">E</a>
<a href="req.html?X_letter=F">F</a>
<a href="req.html?X_letter=G">G</a>
<a href="req.html?X_letter=H">H</a>
<a href="req.html?X_letter=I">I</a>
<a href="req.html?X_letter=J">J</a>
<a href="req.html?X_letter=K">K</a>
<a href="req.html?X_letter=L">L</a>
<a href="req.html?X_letter=M">M</a>
<a href="req.html?X_letter=N">N</a>
<a href="req.html?X_letter=O">O</a>
<a href="req.html?X_letter=P">P</a>
<a href="req.html?X_letter=Q">Q</a>
<a href="req.html?X_letter=R">R</a>
<a href="req.html?X_letter=S">S</a>
<a href="req.html?X_letter=T">T</a>
<a href="req.html?X_letter=U">U</a>
<a href="req.html?X_letter=V">V</a>
<a href="req.html?X_letter=W">W</a>
<a href="req.html?X_letter=X">X</a>
<a href="req.html?X_letter=Y">Y</a>
<a href="req.html?X_letter=Z">Z</a>

Ⅱ．XSLT 2.0 ソリューション:

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:my="my:my" exclude-result-prefixes="xs my"
    xmlns="http://www.w3.org/1999/xhtml">
    <xsl:output omit-xml-declaration="yes" method="xhtml" indent="yes"/>

    <xsl:param name="pStart" as="xs:integer" select="65"/>
    <xsl:param name="pEnd" as="xs:integer" select="90"/>

    <xsl:variable name="vCodes" as="xs:integer*" select=
     "for $i in $pStart to $pEnd
       return $i
     "/>

 <xsl:template match="/">
   <html>
       <xsl:sequence select="my:alphabet()"/>
   </html>
 </xsl:template>

 <xsl:function name="my:alphabet" as="element()*">
  <xsl:for-each select="$vCodes">
    <xsl:variable name="vChar" select="codepoints-to-string(.)"/>
    <a href="req.html?X_letter={$vChar}">
     <xsl:sequence select="$vChar"/>
    </a>
  </xsl:for-each>
 </xsl:function>
</xsl:stylesheet>
于 2011-11-26T16:38:01.280 に答える
0

要素コンテンツ内で、次のaように出力エスケープを無効にすることができます

<a href="req.html?X_letter={$iLetter}">
  <xsl:value-of select="concat('&amp;#', $iLetter, ';')" disable-output-escaping="yes"/>
</a>

ただし、そのアプローチは属性ノード内では機能しないため、文字ではなく文字コードを渡すためにその部分を残しました。

また、disable-output-escaping はオプションのシリアル化機能であり、すべての XSLT プロセッサでサポートされているわけではないことにも注意してください。たとえば、Firefox/Mozilla の組み込み XSLT プロセッサは結果ツリーをシリアル化しませんが、単純にレンダリングするため、アプローチは行われません。仕事に。

于 2011-11-26T11:59:15.377 に答える
0

XSLT 2.0 には という機能がありますcodepoints-to-string()。多くの XSLT 1.0 プロセッサでは、同じ関数を拡張関数として実装するのは簡単ですが、コードがそのプロセッサに依存するようになります。

于 2011-11-27T10:10:19.027 に答える
0

Martin が示唆しているように、disable-output-escaping の使用は避けたほうがよいでしょう。数値文字参照の代わりに単純なASCII文字で満足する場合は、それも必要ありません。その場合、次のように部分文字列とアルファベット検索文字列を使用できます。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="alphabet" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>

    <xsl:template name="alphabet"> 
        <xsl:param name="iLetter" select="65"/> 
        <xsl:if test="$iLetter &lt; 91"> 
            <a>
                <xsl:attribute name="href">req.html?X_letter=<xsl:value-of select="substring($alphabet, $iLetter - 64, 1)"/></xsl:attribute>
                <xsl:value-of select="substring($alphabet, $iLetter - 64, 1)"/>
            </a> 
            <xsl:call-template name="alphabet"> 
                <xsl:with-param name="iLetter" select="number($iLetter)+1"/> 
            </xsl:call-template> 
        </xsl:if> 
    </xsl:template> 

    <xsl:template match="/">
        <xsl:call-template name="alphabet"/> 
    </xsl:template>
</xsl:stylesheet>

乾杯！

于 2011-11-26T13:39:18.113 に答える