10

次のコードを使用してフォームを透明にしていますが、アプリケーションで VCL スタイルが有効になっている場合、フォームは透明ではなく VCL スタイルの背景色でペイントされます。

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TForm1 = class(TForm)
    procedure FormShow(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    procedure CreateParams(var Params:TCreateParams); override;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.CreateParams(var Params: TCreateParams);
begin
 inherited CreateParams(Params);
 Params.ExStyle := WS_EX_TRANSPARENT or WS_EX_TOPMOST;
 //Params.ExStyle := Params.ExStyle or WS_EX_LAYERED;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 Brush.Style:=bsClear;
 BorderStyle:=bsNone;
 //SetLayeredWindowAttributes(Handle, 0, 230, $00000002);
end;

参考までに、vcl スタイルが に設定されている場合、コードは正常に動作しWindowsます。

この問題を回避するためにフォームを透明にする別の方法はありますか?

4

3 に答える 3

12

私にはバグのようです。VCL スタイルは、スタイル フックを使用して、ペイント メソッドとこれらの操作に関連する Windows メッセージをインターセプトします。したがって、この場合、 にあるクラスのPaintBackgroundメソッドに 注意を向ける必要があります。ここから、新しいスタイル フック クラスを作成します ( TFormStyleHookの子孫）、メソッドをオーバーライドし、コードを修正し、最後にそれを使用する前に RegisterStyleHook メソッドを呼び出して新しいスタイル フックを登録します。この記事をチェックして、例を確認してください。TFormStyleHookVcl.FormsPaintBackgroundFixing a VCL Style bug in the TPageControl and TTabControl components

更新 このサンプルを確認してください

unit Unit138;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs;

type
  TForm138 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    procedure CreateParams(var Params:TCreateParams); override;
  public
  end;


var
  Form138: TForm138;

implementation

 Uses
   Vcl.Themes,
   Vcl.Styles,
   uPatch;

{$R *.dfm}

procedure TForm138.CreateParams(var Params: TCreateParams);
begin
 inherited CreateParams(Params);
 Params.ExStyle := WS_EX_TRANSPARENT or WS_EX_TOPMOST;
end;

procedure TForm138.FormCreate(Sender: TObject);
begin
 Brush.Style:=bsClear;
 BorderStyle:=bsNone;
end;

initialization
 TStyleManager.Engine.UnRegisterStyleHook(TForm, TFormStyleHook);//unregister the original style hook
 TStyleManager.Engine.RegisterStyleHook(TForm, TMyStyleHookClass); //register the new style hook

end.

新しいスタイルのフック クラス

unit uPatch;

interface

uses
  Vcl.Graphics,
  Vcl.Forms;

type
  TMyStyleHookClass= class(TFormStyleHook)
  protected
   procedure PaintBackground(Canvas: TCanvas); override;
  end;

implementation

uses
  Winapi.Windows,
  System.Types,
  Vcl.Themes;


procedure TMyStyleHookClass.PaintBackground(Canvas: TCanvas);
{This is only a basic sample for fix a specific scenario}
var
  Details: TThemedElementDetails;
  R: TRect;
begin
  if StyleServices.Available then
  begin
    if (GetWindowLong(Form.Handle,GWL_EXSTYLE) AND WS_EX_TRANSPARENT) = WS_EX_TRANSPARENT  then
    if Form.Brush.Style = bsClear then Exit;

    Details.Element := teWindow;
    Details.Part := 0;
    R := Rect(0, 0, Control.ClientWidth, Control.ClientHeight);
    StyleServices.DrawElement(Canvas.Handle, Details, R);
  end;
end;

end.
于 2011-11-29T21:57:52.277 に答える
2

別のメモとして、でウィンドウ スタイルを操作する代わりにTransparentColorおよびTranparentColorValueプロパティを使用してみましたCreateParams()か?

于 2011-11-29T22:58:25.027 に答える
1

OverridePaintNC：= Falseを使用して、NC領域にスタイルを描画しないようにします。そして、OverrideEraseBkgndもあります。多分これは助けになります。

于 2011-11-29T23:59:32.603 に答える