1

属性値を計算するにはどうすればよいですか? 次に例を示します。

(declare-fun x () bool)
(declare-fun y () bool)
(declare-fun z () bool)
(assert (AND x (OR y z)))

これで私は2つのモデルを取得します:

x=true and y=true
x=true and z=true

今、私が欲しいのは次のようなものです：

(declare-fun x () bool)
(declare-fun y () bool)
(declare-fun z () bool)
(declare-fun x.val () Int)
(declare-fun y.val () Int)
(declare-fun z.val () Int)
(assert (= x.val 2))
(assert (= y.val 3))
(assert (= z.val 5))
(assert (AND x (OR y z)))
(assert (> sum 6))

したがって、属性の合計が 6 より大きいモデルを取得したいと思います。

x=true and z=true

たぶん、配列を操作することがこれを達成する方法です...

4

2 に答える 2

2

あなたの質問を正しく理解したかどうかはわかりません。（整数）属性を各ブール変数に関連付けたいようです。したがって、各変数はペアです。ブール値と整数属性です。によってsum、trueに割り当てられた変数の属性の合計を意味していると思います。その場合は、次の方法でZ3でモデル化できます。

;; Enable model construction
(set-option :produce-models true)

;; Declare a new type (sort) that is a pair (Bool, Int).
;; Given a variable x of type/sort WBool, we can write
;;  - (value x) for getting its Boolean value
;;  - (attr x)  for getting the integer "attribute" value
(declare-datatypes () ((WBool (mk-wbool (value Bool) (attr Int)))))

;; Now, we declare a macro int-value that returns (attr x) if
;; (value x) is true, and 0 otherwise
(define-fun int-value ((x WBool)) Int
  (ite (value x) (attr x) 0))

(declare-fun x () WBool)
(declare-fun y () WBool)
(declare-fun z () WBool)

;; Set the attribute values for x, y and z
(assert (= (attr x) 2))
(assert (= (attr y) 3))
(assert (= (attr z) 5))

;; Assert Boolean constraint on x, y and z.
(assert (and (value x) (or (value y) (value z))))

;; Assert that the sum of the attributes of the variables assigned to true is greater than 6.
(assert (> (+ (int-value x) (int-value y) (int-value z)) 6))
(check-sat)
(get-model)

(assert (not (value z)))
(check-sat)
于 2011-12-05T16:15:52.590 に答える
1

3 つの変数を使用すると、次のようになると思います。

(define-fun cond_add ((cond Bool) (x Int) (sum Int)) Int
  (ite cond (+ sum x) sum))
(declare-fun sum () Int)
(assert (= sum (cond_add x x.val (cond_add y y.val (cond_add z z.val 0)))))
(assert (> sum 6))

cond_addここでは、対応する条件が成立したときにアキュムレータに変数を追加するマクロを定義します。Andは、との真理値に基づいて、とsumの条件付き和を説明するように定義されています。x.valy.valz.valxyz

于 2011-12-05T16:12:49.907 に答える