5

Delphi Chromium Embedded（http://code.google.com/p/delphichromiumembedded）のTChromiumブロザーを持っています。コンテキストメニューを付けたいのですが。どうすればそれを達成できますか？

4

2 に答える 2

5

OnBeforeMenuイベントを処理する必要があります。Resultその場合、ハンドラーは、出力パラメーターをTrueデフォルトのコンテキストメニューがポップアップするのを抑制するものに設定するのに十分です。その後、menuInfo構造から取得した位置に独自のメニューを表示できます。

カスタムポップアップメニューを使用したコードサンプルは次のとおりです。

uses
  ceflib, cefvcl;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Chromium1.Load('www.example.com');
end;

procedure TForm1.Chromium1BeforeMenu(Sender: TObject;
  const browser: ICefBrowser; const menuInfo: PCefHandlerMenuInfo;
  out Result: Boolean);
begin
  Result := True;
  PopupMenu1.Popup(menuInfo.x, menuInfo.y);
end;

procedure TForm1.PopupMenuItemClick(Sender: TObject);
begin
  ShowMessage('You''ve clicked on a custom popup item :)');
end;

アップデート：

動的に作成されたインスタンスの場合、イベントハンドラーを手動で割り当てる必要があります。次のコードを試してください。

uses
  ceflib, cefvcl;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    PopupMenu1: TPopupMenu;
    procedure Button1Click(Sender: TObject);
  private
    procedure ChromiumOnBeforeMenu(Sender: TObject;
      const browser: ICefBrowser; const menuInfo: PCefHandlerMenuInfo;
      out Result: Boolean);
  public
    { Public declarations }
  end;

implementation

procedure Form1.ChromiumOnBeforeMenu(Sender: TObject; const browser: ICefBrowser;
  const menuInfo: PCefHandlerMenuInfo; out Result: Boolean);
begin
  Result := True;
  PopupMenu1.Popup(menuInfo.x, menuInfo.y);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Chromium: TChromium;
begin
  // owner is responsible for destroying the component
  // in this case you are telling to Panel1 to destroy
  // the Chromium instance before he destroys itself,
  // it doesn't affect the event handling
  Chromium := TChromium.Create(Panel1);

  Chromium.Parent := Panel1;
  Chromium.Left := 10;
  Chromium.Top := 10;
  Chromium.Width := Panel1.Width - 20;
  Chromium.Height := Panel1.Height - 20;

  // this line is important, you are assigning the event
  // handler for OnBeforeMenu event, so in fact you tell
  // to the Chromium; hey if the OnBeforeMenu fires, run
  // the code I'm pointing at, in this case will execute
  // the ChromiumOnBeforeMenu procedure
  Chromium.OnBeforeMenu := ChromiumOnBeforeMenu;

  Chromium.Load('www.example.com');
end;
于 2011-12-07T01:05:36.670 に答える
4

実際には、popupmenuは必要ありません。また、すでにchromiumのコンテキストメニューを作成できる場合は、vcl.menusユニットをアプリケーションに追加する必要はありません。また、クロム独自のメニューは、ビンテージのwin32 apiライブラリを使用するvclよりも、よりモダンでクリアな外観で、描画パフォーマンスが高速です。

cef3のメニューは、このように完全に構​​成可能です。

 procedure Tfmmain.Chromium1BeforeContextMenu(Sender: TObject;
    const browser: ICefBrowser; const frame: ICefFrame;
    const params: ICefContextMenuParams; const model: ICefMenuModel);
  begin
    model.Clear;
    model.AddItem(1, 'Your Command 1');
    model.AddItem(2, 'Your Command 2');
    model.AddSeparator;
    model.AddItem(3, 'Your Command 3');
    model.AddItem(4, 'your Command 4');
    model.AddSeparator;
    model.AddItem(999, 'Quit');

    model.SetAccelerator(1, VK_RIGHT, false, false, false);
    model.SetAccelerator(2, VK_LEFT, false, false, false);

    model.SetAccelerator(3, VK_DOWN, false, false, false);
    model.SetAccelerator(4, VK_UP, false, false, false);

    model.SetAccelerator(999, VK_ESCAPE, false, false, false);

  end;

  procedure Tfmmain.Chromium1ContextMenuCommand(Sender: TObject;
    const browser: ICefBrowser; const frame: ICefFrame;
    const params: ICefContextMenuParams; commandId: Integer;
    eventFlags: TCefEventFlags; out Result: Boolean);
  begin
    case commandId of
      1:
        begin
           DoIt1;
          Result := true;
        end;
      2:
        begin
         DoIt2;
          Result := true;
        end;
      3:
        begin
        DoIt3;
          Result := true;
        end;
      4:
       DoIt4;
          Result := true;
        end;
      999:
        begin
          Application.MainForm.Close;
           Result := true;
        end;
    end;

  end;

注：SetAcceleratorショートカットは、ポップアップが表示された場合にのみ機能するため、onPreKeyEventが必要になる場合があります

于 2015-05-29T10:12:49.677 に答える