8

Arduino Unoの GSM/GPRSシールドを使用して電話をかけ、SMS を送信する方法を知っています。しかし、ロケーション に Web サービスがあり、GSM/GPRS シールドを使用してセンサー データをこの URL に送信したいと考えています。これは、動作ロケーションに Wi-Fi が存在することを期待できないためです。これは私が持っているシールドです。3G SIM カードも持っていて、Arduino Uno で実行しています。http://mydomain.com/rest/receiveSensorData

どうすればいいですか？

4

2 に答える 2

10

おそらくすでにこれが機能していますが、念のために：

私のセットアップでは、Sim900 モジュールを使用する Seeed Quad Band GPRS Shield を使用しています。あなたの仕様を見た後、このコードはあなたのものでも機能すると思います。

    #include <SoftwareSerial.h>
SoftwareSerial gprsSerial(7, 8);

void setup()
{
  gprsSerial.begin(19200);
  Serial.begin(19200);

  Serial.println("Config SIM900...");
  delay(2000);
  Serial.println("Done!...");
  gprsSerial.flush();
  Serial.flush();

  // attach or detach from GPRS service 
  gprsSerial.println("AT+CGATT?");
  delay(100);
  toSerial();


  // bearer settings
  gprsSerial.println("AT+SAPBR=3,1,\"CONTYPE\",\"GPRS\"");
  delay(2000);
  toSerial();

  // bearer settings
  gprsSerial.println("AT+SAPBR=3,1,\"APN\",\"epc.tmobile.com\"");
  delay(2000);
  toSerial();

  // bearer settings
  gprsSerial.println("AT+SAPBR=1,1");
  delay(2000);
  toSerial();
}


void loop()
{
   // initialize http service
   gprsSerial.println("AT+HTTPINIT");
   delay(2000); 
   toSerial();

   // set http param value
   gprsSerial.println("AT+HTTPPARA=\"URL\",\"http://YOUR.DOMAIN.COM/rest/receiveSensorData?sensorval1=blah&sensorval2=blah\"");
   delay(2000);
   toSerial();

   // set http action type 0 = GET, 1 = POST, 2 = HEAD
   gprsSerial.println("AT+HTTPACTION=0");
   delay(6000);
   toSerial();

   // read server response
   gprsSerial.println("AT+HTTPREAD"); 
   delay(1000);
   toSerial();

   gprsSerial.println("");
   gprsSerial.println("AT+HTTPTERM");
   toSerial();
   delay(300);

   gprsSerial.println("");
   delay(10000);
}

void toSerial()
{
  while(gprsSerial.available()!=0)
  {
    Serial.write(gprsSerial.read());
  }
}

「epc.tmobile.com」をキャリアの apn に、「YOUR.DOMAIN.COM」をサーバー情報に変更し、「sensorval1=blah」を変数とセンサー データに変更するだけです。

これがうまくいくかどうか教えてください。難しすぎないことを理解するのを手伝うことができます。

幸運を。

于 2013-02-23T13:31:11.307 に答える
0

実際には、データが小さく、Web アプリケーションに SMS 情報を受信する機能を追加すると、SMS を送信し続ける方が簡単になる場合があります。

次の質問への回答を参照してください。

ホストされたサーバー上の米国の Web アプリケーションで SMS メッセージを受信する

SMS を使用する利点の 1 つは、一般に時間がかかり、より多くの電力を使用する可能性がある GPRS 接続を設定する必要があるシールドを節約できることです。1 つの欠点として、SMS は保証されたメッセージング システムではないことに注意してください。

余談ですが、3G SIM を持っていても、モデムが 3G もサポートしていない限り、GPRS モデムで 3G を使用することはできません。

于 2012-01-11T23:17:58.777 に答える