8

f2py でコンパイルしようとしている Fortran モジュールがあります (下記参照)。モジュール宣言を削除してサブルーチンをファイルにそのまま残すと、すべて正常に動作します。ただし、モジュールが次のように宣言されている場合、次の結果が得られます。

> f2py.py -c -m its --compiler=mingw itimes-s2.f
...
Reading fortran codes...
    Reading file 'itimes-s2.f' (format:fix,strict)
crackline: groupcounter=1 groupname={0: '', 1: 'module', 2: 'interface', 3: 'subroutine'}
crackline: Mismatch of blocks encountered. Trying to fix it by assuming "end" statement.
...
c:\users\astay13\appdata\local\temp\tmpgh5ag8\Release\users\astay13\appdata\local\temp\tmpgh5ag8\src.win32-3.2\itsmodule.o:itsmodule.c:(.data+0xec): undefined reference to `itimes_'
collect2: ld returned 1 exit status

f2py でのモジュールまたはサブルーチンのコンパイルの違いは何ですか? f2py に問題を引き起こす重要なものをモジュールに置き忘れていませんか? gfortran を単独で使用すると、モジュールが正常にコンパイルされることに注意してください。

ソフトウェア: Windows 7; gcc、gfortran 4.6.1 (MinGW); パイソン3.2.2; f2py v2

itimes-s2.f:

  module its

  contains

  subroutine itimes(infile,outfile)

    implicit none

    ! Constants
    integer, parameter :: dp = selected_real_kind(15)

    ! Subroutine Inputs
    character(*), intent(in) :: infile
    character(*), intent(in) :: outfile

    ! Internal variables
    real(dp) :: num
    integer :: inu
    integer :: outu
    integer :: ios

    inu = 11
    outu = 22

    open(inu,file=infile,action='read')
    open(outu,file=outfile,action='write',access='append')

    do
      read(inu,*,IOSTAT=ios) num
      if (ios < 0) exit

      write(outu,*) num**2
    end do

  end subroutine itimes

  end module its
4

3 に答える 3

10

PythonモジュールにFortranモジュールを入れようとしています。あなたがそれを望むなら、名前は異なっていなければなりません、例えば

 f2py.py -c -m SOMEDIFFERENTNAME itimes-s2.f

結果はとして呼び出されpythonmodule.fortranmodule.yourfunction()ます。

次のようにインポートすることもできます

from pythonmodule import fortranmodule
fortranmodule.yourfunction()

そうでなければ、それは私のマシンで動作しました。

于 2011-12-20T08:36:36.147 に答える
2

f2py が機能するためには、インターフェイスの作成を指示する署名ファイルが必要です。または、インターフェイスを支援する f2py コメントでソース コードを変更する必要があります。詳細については、 http://cens.ioc.ee/projects/f2py2e/usersguide/#signature-fileを参照してください。

そのサイトから：

C FILE: FIB3.F
      SUBROUTINE FIB(A,N)
C
C     CALCULATE FIRST N FIBONACCI NUMBERS
C
      INTEGER N
      REAL*8 A(N)
Cf2py intent(in) n
Cf2py intent(out) a
Cf2py depend(n) a
      DO I=1,N
         IF (I.EQ.1) THEN
            A(I) = 0.0D0
         ELSEIF (I.EQ.2) THEN
            A(I) = 1.0D0
         ELSE 
            A(I) = A(I-1) + A(I-2)
         ENDIF
      ENDDO
      END
C END FILE FIB3.F

拡張モジュールのビルドは、1 つのコマンドで実行できるようになりました。

f2py -c -m fib3 fib3.f
于 2011-12-19T17:41:41.693 に答える