2

Easy 68K シミュレーターを使用して単純なブラック ジャック ゲームを作成しており、乱数を使用してカードを割り当てる必要があります。私のカードは 2 から 11 の範囲内にある必要があります。毎回同じ数字を取得しているように見えますが、期待した範囲内ではありません。私のカードの値は D3 になる必要があるため、次の乱数コードがあります。

 CLR.L       D0
 CLR.L       D3
 MOVE.B      #8, D0         ;Access time
 TRAP        #15
 AND.L       #$5FFFFF,D1    ;prevent overflow in divu
 DIVU        #10, D1
 SWAP        D1
 ADDQ.W      #1, D1
 MOVE        D1, D3

このサイトのコードを変更することで得たもの: https://notendur.hi.is/voe1/3.%20onn/Tolvuhogun/EASy68K/Examples/tutorial3.X68

2 から 11 までの数を生成する方法を見つけたいと思っています。インターネットで数時間検索しています。Move.B #8, D0 を使用して時間にアクセスする必要があることはわかっていますが、それ以上はあまり進歩していません。どんな助けでも大歓迎です！

4

2 に答える 2

5

AND.L(「divu でのオーバーフローの防止」) で使用されているマスクは、100 で割る場合にのみ有効でした。10 で割るには、でマスクする必要があります0x7FFFF。

どうして：

0xFFFFFFFF / #100 = 0x28f5c28 - too big for a single word!
0x5FFFFF   / #100 = 0xF5C2    - that fits

0x5FFFFF / #10  = 0x99999 - too big for a single word!
0x7FFFF  / #10  = 0xCCCC  - that fits

さらに、あなたが持っているコードは、1 から 10 (0-9 + 1) までの数字を与えます。2 から 11 が必要な場合は、1 ではなく 2 を追加する必要があります。

これは、Mac OS QuickDraw ソース コードから借用した、より高度な乱数ジェネレーターです。構文をいくらか翻訳する必要があるかもしれないことに注意してください (25 年以上前に書かれたものです!) および/またはシードをロードおよび保存する方法を変更する必要があります。

;--------------------------------------------------------------
;
;  FUNCTION Random: INTEGER;
;
;  returns a signed 16 bit number, and updates unsigned 32 bit randSeed.
;
;  recursion is randSeed := (randSeed * 16807) MOD 2147483647.
;
;  See paper by Linus Schrage, A More Portable Fortran Random Number Generator
;  ACM Trans Math Software Vol 5, No. 2, June 1979, Pages 132-138.
;
;  Clobbers D0-D2, A0
;
;
;  GET LO 16 BITS OF SEED AND FORM LO PRODUCT
;  xalo := A * LoWord(seed)
;
        MOVE.L  GRAFGLOBALS(A5),A0      ;POINT TO QuickDraw GLOBALS
        MOVE    #16807,D0               ;GET A = 7^5
        MOVE    D0,D2                   ;GET A = 7^5
        MULU    RANDSEED+2(A0),D0       ;CALC LO PRODUCT = XALO
;
;  FORM 31 HIGHEST BITS OF LO PRODUCT
;  fhi:=HiWord(seed) * ORD4(a) + HiWord(xalo);
;
        MOVE.L  D0,D1                   ;COPY xalo
        CLR.W   D1
        SWAP    D1                      ;GET HiWord(xalo) as a long
        MULU    RANDSEED(A0),D2         ;MULT BY HiWord(seed)
        ADD.L   D1,D2                   ;ADD LEFTLO = FHI
;
;  GET OVERFLOW PAST 31ST BIT OF FULL PRODUCT
;  k:=fhi DIV 32768;
;
        MOVE.L  D2,D1                   ;COPY FHI
        ADD.L   D1,D1                   ;CALC 2 TIMES FHI
        CLR.W   D1
        SWAP    D1                      ;CALC FHI SHIFTED RIGHT 15 FOR K
;
;  ASSEMBLE ALL THE PARTS AND PRE-SUBTRACT P
;  seed:=((BitAnd(XALO,$0000FFFF) - P) + BitAnd(fhi,$00007FFF) * b16) + K;
;
        AND.L   #$0000FFFF,D0           ;GET LO WORD XALO
        SUB.L   #$7FFFFFFF,D0           ;SUBTRACT P = 2^31-1
        AND.L   #$00007FFF,D2           ;BitAnd(fhi,$00007FFF)
        SWAP    D2                      ;TIMES 64K
        ADD.L   D1,D2                   ;PLUS K
        ADD.L   D2,D0                   ;CALC TOTAL
;
;  IF seed < 0 THEN seed:=seed+p;
;
        BPL.S   UPDATE
        ADD.L   #$7FFFFFFF,D0
UPDATE  MOVE.L  D0,RANDSEED(A0)         ;UPDATE SEED
        CMP.W   #$8000,D0               ;IS NUMBER -32768 ?
        BNE.S   NUMOK                   ;NO, CONTINUE
        CLR     D0                      ;YES, RETURN ZERO INSTEAD
NUMOK   MOVE.W  D0,4(SP)                ;RETURN LO WORD AS RESULT
        RTS
于 2011-12-20T00:39:57.113 に答える