26

NSIS に表示されるインストール ログを保存する最も簡単な方法は何ですか? ログを保存できるようにする特別なフラグを付けて NSIS コードを再コンパイルできることをどこかで読んだことを覚えているようです。もっと簡単な方法はありますか？

4

3 に答える 3

41

ファイル サイズを小さく保つために、NSIS コンパイラのデフォルト インストールではログ ファイルが作成されません。リリースのSpecial Buildをダウンロードし、makensis.exeアプリケーション (およびフォルダー) にコピーしStubてパッチを適用し、ログをサポートします。

それが完了したら、次をスクリプトに追加するだけです。

 LogSet on

他の変更は必要ありません。私の場合のように、これがデフォルトではない理由がわかりません。ファイルサイズに48バイトしか追加されません!

于 2009-09-25T08:27:54.393 に答える
16

NSISLogプラグインを試してください。

LogExもあります。

于 2009-05-14T02:57:59.020 に答える
5

これはNSIS Webサイトからの直接の解決策です

StrCpy $0 "$EXEDIR\install.log"
Push $0
Call DumpLog



!define LVM_GETITEMCOUNT 0x1004
!define LVM_GETITEMTEXT 0x102D

Function DumpLog
  Exch $5
  Push $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $6

  FindWindow $0 "#32770" "" $HWNDPARENT
  GetDlgItem $0 $0 1016
  StrCmp $0 0 exit
  FileOpen $5 $5 "w"
  StrCmp $5 "" exit
    SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
    System::Alloc ${NSIS_MAX_STRLEN}
    Pop $3
    StrCpy $2 0
    System::Call "*(i, i, i, i, i, i, i, i, i) i \
      (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
    loop: StrCmp $2 $6 done
      System::Call "User32::SendMessageA(i, i, i, i) i \
        ($0, ${LVM_GETITEMTEXT}, $2, r1)"
      System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
      FileWrite $5 "$4$\r$\n"
      IntOp $2 $2 + 1
      Goto loop
    done:
      FileClose $5
      System::Free $1
      System::Free $3
  exit:
    Pop $6
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
    Exch $5
FunctionEnd
于 2009-05-14T02:55:05.687 に答える