1

私はこれを読んでいて、混乱して立ち往生しています。

印刷とファイルへのログインを同時に行うには、ALWAYSまたは両方を使用する必要がありますか?print_portfolio('themessage')

私がしたいこと：

if ($logfile) {
   open (FILE, '>>', "logfile");
   print "Hello" #some code from Log4perl#;
   #prints on the display and into the logfile
}

それ以外の：

if ($logfile) { open (FILE, '>>', "logfile"); }
print "Hello";
if ($logfile) { print FILE "Hello"; }
4

1 に答える 1

6

どちらも使用しません。

  • ALWAYS選択したログ レベルに関係なく、常に出力されるログ レベルです。ログ レベルは、選択したレベルに基づいて、ロガーによってログに記録される情報の量を制御する方法です

  • print_portfolioサブルーチンは、画面とファイルに同時にログを記録することとあまり関係のない例です。

Perlセクション内の高度な構成には、ロガーを設定して画面とファイルに同時に出力する方法の明確な例があると思います。

構成ファイルをまったく使用せずに、Perl で同じレイアウトの 2 つのアペンダーを構成する方法の例を次に示します。

########################
# Initialization section
########################
use Log::Log4perl;
use Log::Log4perl::Layout;
use Log::Log4perl::Level;

   # Define a category logger
my $log = Log::Log4perl->get_logger("Foo::Bar");

   # Define a layout
my $layout = Log::Log4perl::Layout::PatternLayout->new("[%r] %F %L %m%n");

   # Define a file appender
my $file_appender = Log::Log4perl::Appender->new(
                        "Log::Log4perl::Appender::File",
                        name      => "filelog",
                        filename  => "/tmp/my.log");

   # Define a stdout appender
my $stdout_appender =  Log::Log4perl::Appender->new(
                        "Log::Log4perl::Appender::Screen",
                        name      => "screenlog",
                        stderr    => 0);

   # Have both appenders use the same layout (could be different)
$stdout_appender->layout($layout);
$file_appender->layout($layout);

$log->add_appender($stdout_appender);
$log->add_appender($file_appender);
$log->level($INFO);
于 2011-12-23T21:12:01.737 に答える