12

ReadDirectoryChangesW を使用して、指定されたディレクトリを監視し、変更が検出されるたびにインデックス構造を更新します。次のコードを使用します（大まかに）

var
  InfoPointer : PFileNotifyInformation;
  NextOffset : DWORD;
...
while (not Terminated) do begin
  if ReadDirectoryChangesW (FDirHandle, FBuffer, FBufferLength, True,
                            FFilter, @BytesRead, @FOverlap, nil) then
    begin
    WaitResult := WaitForMultipleObjects (2, @FEventArray, False, INFINITE);
    if (WaitResult = waitFileChange) then
      begin 
      InfoPointer := FBuffer;
      repeat
        NextOffset := InfoPointer.NextEntryOffset;
        ...
        PByte (InfoPointer) := PByte (InfoPointer) + NextOffset;
      until NextOffset = 0;
      end;
    end;
end;

フィルターは

FFilter :=  FILE_NOTIFY_CHANGE_FILE_NAME or
            FILE_NOTIFY_CHANGE_DIR_NAME or
            FILE_NOTIFY_CHANGE_SIZE or
            FILE_NOTIFY_CHANGE_LAST_WRITE;

ディレクトリハンドルは次のように取得されます。

FDirHandle := CreateFile (PChar (FDirectoryWatch.WatchedDirectory),
                          FILE_LIST_DIRECTORY or GENERIC_READ,
                          FILE_SHARE_READ or FILE_SHARE_WRITE or FILE_SHARE_DELETE,
                          nil, OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS or   
                          FILE_FLAG_OVERLAPPED, 0);

複数のファイルを削除すると、イベントが 1 つしか発生せず、NextOffset は 0 です! また、ディレクトリを削除すると、そのディレクトリのイベントが 1 つだけ取得されます。ディレクトリ内のファイルごとに 1 つのイベントが必要な場合はどうすればよいですか?

どんな助けでも大歓迎です。

4

2 に答える 2

17

ReadDirectoryChangesW()を使用するさまざまな方法を混在させているようです。ディレクトリを開くときにFILE_FLAG_OVERLAPPEDフラグを指定し、 lpOverlappedパラメータへのポインタを指定します。これは、構造内のイベントを待機して処理することを意味します。非同期 I/O; 同時に、ワーカー スレッドのループでReadDirectoryChangesW()を呼び出します。専用スレッドがあり、同期モードを使用できるため、最初にlpOverlappedをnilに設定して再試行します。

ReadDirectoryChangesW() API 関数のドキュメントでは、さまざまな使用方法が説明されています。バッファがオーバーフローする可能性もあるため、変更イベントが失われる可能性があることに注意してください。ディレクトリの内容のスナップショットを比較することも同様に機能する可能性があるため、この機能のみに依存するという戦略を再考する必要があるかもしれません。

編集：

編集したコードの見栄えが良くなります。ただし、私のテストでは、ReadDirectoryChangesW()は宣伝どおりに機能し、返されたバッファーに複数のデータ エントリがあったか、処理するバッファーが複数あったかのいずれかでした。これはタイミングによって異なります。Delphi でブレークポイントに到達した後、1 つのバッファに複数のエントリが表示されます。

完全を期すために、Delphi 5 を使用して実装されたテスト コードを添付します。

type
  TWatcherThread = class(TThread)
  private
    fChangeHandle: THandle;
    fDirHandle: THandle;
    fShutdownHandle: THandle;
  protected
    procedure Execute; override;
  public
    constructor Create(ADirectoryToWatch: string);
    destructor Destroy; override;

    procedure Shutdown;
  end;

constructor TWatcherThread.Create(ADirectoryToWatch: string);
const
  FILE_LIST_DIRECTORY = 1;
begin
  inherited Create(TRUE);
  fChangeHandle := CreateEvent(nil, FALSE, FALSE, nil);
  fDirHandle := CreateFile(PChar(ADirectoryToWatch),
    FILE_LIST_DIRECTORY or GENERIC_READ,
    FILE_SHARE_READ or FILE_SHARE_WRITE or FILE_SHARE_DELETE,
    nil, OPEN_EXISTING, FILE_FLAG_BACKUP_SEMANTICS or FILE_FLAG_OVERLAPPED, 0);
  fShutdownHandle := CreateEvent(nil, FALSE, FALSE, nil);
  Resume;
end;

destructor TWatcherThread.Destroy;
begin
  if fDirHandle <> INVALID_HANDLE_VALUE then
    CloseHandle(fDirHandle);
  if fChangeHandle <> 0 then
    CloseHandle(fChangeHandle);
  if fShutdownHandle <> 0 then
    CloseHandle(fShutdownHandle);
  inherited Destroy;
end;

procedure TWatcherThread.Execute;
type
  PFileNotifyInformation = ^TFileNotifyInformation;
  TFileNotifyInformation = record
    NextEntryOffset: DWORD;
    Action: DWORD;
    FileNameLength: DWORD;
    FileName: WideChar;
  end;
const
  BufferLength = 65536;
var
  Filter, BytesRead: DWORD;
  InfoPointer: PFileNotifyInformation;
  Offset, NextOffset: DWORD;
  Buffer: array[0..BufferLength - 1] of byte;
  Overlap: TOverlapped;
  Events: array[0..1] of THandle;
  WaitResult: DWORD;
  FileName, s: string;
begin
  if fDirHandle <> INVALID_HANDLE_VALUE then begin
    Filter := FILE_NOTIFY_CHANGE_FILE_NAME or FILE_NOTIFY_CHANGE_DIR_NAME
      or FILE_NOTIFY_CHANGE_SIZE or FILE_NOTIFY_CHANGE_LAST_WRITE;

    FillChar(Overlap, SizeOf(TOverlapped), 0);
    Overlap.hEvent := fChangeHandle;

    Events[0] := fChangeHandle;
    Events[1] := fShutdownHandle;

    while not Terminated do begin
      if ReadDirectoryChangesW (fDirHandle, @Buffer[0], BufferLength, TRUE,
        Filter, @BytesRead, @Overlap, nil)
      then begin
        WaitResult := WaitForMultipleObjects(2, @Events[0], FALSE, INFINITE);
        if WaitResult = WAIT_OBJECT_0 then begin
          InfoPointer := @Buffer[0];
          Offset := 0;
          repeat
            NextOffset := InfoPointer.NextEntryOffset;
            FileName := WideCharLenToString(@InfoPointer.FileName,
              InfoPointer.FileNameLength);
            SetLength(FileName, StrLen(PChar(FileName)));
            s := Format('[%d] Action: %.8xh, File: "%s"',
               [Offset, InfoPointer.Action, FileName]);
            OutputDebugString(PChar(s));
            PByte(InfoPointer) := PByte(DWORD(InfoPointer) + NextOffset);
            Offset := Offset + NextOffset;
          until NextOffset = 0;
        end;
      end;
    end;
  end;
end;

procedure TWatcherThread.Shutdown;
begin
  Terminate;
  if fShutdownHandle <> 0 then
    SetEvent(fShutdownHandle);
end;

////////////////////////////////////////////////////////////////////////////////

procedure TForm1.FormCreate(Sender: TObject);
begin
  fThread := TWatcherThread.Create('D:\Temp');
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if fThread <> nil then begin
    TWatcherThread(fThread).Shutdown;
    fThread.Free;
  end;
end;

ディレクトリを削除すると、ディレクトリに含まれるファイルには何も返されず、1 つの変更のみが返されます。ただし、親ディレクトリのハンドルのみを見ているので、それは理にかなっています。サブディレクトリの通知が必要な場合は、おそらくそれらも監視する必要があります。

于 2009-05-14T15:30:23.297 に答える
4

特に多くの変更が同時に発生した場合、イベントを失うという同じ問題がありました。500 個のファイルが監視対象ディレクトリにコピーされます。

最終的にCromisを見つけ、 Directory watchを使用しました。二度と振り返ることはありません。

于 2012-05-04T07:50:49.430 に答える