4

Win32 API の Window-Procedure は、クラス オブジェクト ( this) パラメータを受け取ることができないため、静的 \ グローバル関数でなければなりません。もちろん、hWnd->object ディクショナリなどの回避策を使用できます。

Dには、オブジェクトごとに小さなメンバー関数のコピーを作成する（オブジェクトの実際のハンドラーを呼び出す）、または割り当てることができる無名関数WNDCLASS.lpfnWndProc（無名関数があることは知っていますが、使用できません）など、エレガントに解決する方法があるのだろうかそれらのextern(Windows)プロパティ）？

私はこのようなことをすることができます:

class Window {
    extern (Windows)
    LRESULT delegate (HWND hWnd, UINT msg, WPARAM w, LPARAM l) MyWinProcDelegate;

    this() {
        MyWinProcDelegate = &Events;
    }

    extern (Windows)
    LRESULT Events (HWND hWnd, UINT msg, WPARAM w, LPARAM l) {
        MessageBoxA(null , "Success!!!" , null ,0);
        return DefWindowProcA(hWnd, message, wParam, lParam);
    }
}

(registration\creation\msg-loopは省略…)

Events() が起動していないようです...何か不足していますか?

4

3 に答える 3

3

ここで私はあなたのためにこれを作りました（BCSの答えに基づいて）：

version (Windows)
{
    import std.c.windows.windows;

    void makeExecutable(ubyte[] code)
    {
        DWORD old;
        VirtualProtect(code.ptr, code.length, PAGE_EXECUTE_READWRITE, &old);
    }
}
else
version (linux)
{
    import core.sys.posix.sys.mman;
    import core.sys.posix.unistd;

    static if (!is(typeof(&mprotect)))
        extern(C) int mprotect(void*, size_t, int);

    void makeExecutable(ubyte[] code)
    {
        auto pageSize = sysconf(_SC_PAGE_SIZE);
        auto address = ((cast(size_t)code.ptr) & ~(pageSize-1));
        int pageCount =
            (address/pageSize == (address+code.length)/pageSize) ? 1 : 2;
        mprotect(cast(void*)address, pageSize * pageCount,
            PROT_READ | PROT_WRITE | PROT_EXEC);
    }
}
else
    static assert(0, "TODO");

R function(A) delegate2function(R, A...)(R delegate(A) d)
{
    enum size_t TEMPLATE1 = cast(size_t)0x01234567_01234567;
    enum size_t TEMPLATE2 = cast(size_t)0x89ABCDEF_89ABCDEF;

    static R functionTemplate(A args)
    {
        R delegate(A) d;
        d.ptr     = cast(typeof(d.ptr    ))TEMPLATE1;
        d.funcptr = cast(typeof(d.funcptr))TEMPLATE2;
        return d(args);
    }

    static void functionTemplateEnd() {}

    static void replaceWord(ubyte[] a, size_t from, size_t to)
    {
        foreach (i; 0..a.length - size_t.sizeof + 1)
        {
            auto p = cast(size_t*)(a.ptr + i);
            if (*p == from)
            {
                *p = to;
                return;
            }
        }
        assert(0);
    }

    auto templateStart = cast(ubyte*)&functionTemplate;
    auto templateEnd   = cast(ubyte*)&functionTemplateEnd;
    auto templateBytes = templateStart[0 .. templateEnd - templateStart];

    // must allocate type with pointers, otherwise GC won't scan it
    auto functionWords = new void*[(templateBytes.length / (void*).sizeof) + 3];
    // store context in word-aligned boundary, so the GC can find it
    functionWords[0] = d.ptr;
    functionWords[1] = d.funcptr;
    functionWords = functionWords[2..$];

    auto functionBytes = (cast(ubyte[])functionWords)[0..templateBytes.length];
    functionBytes[] = templateBytes[];

    replaceWord(functionBytes, TEMPLATE1, cast(size_t)d.ptr    );
    replaceWord(functionBytes, TEMPLATE2, cast(size_t)d.funcptr);
    makeExecutable(functionBytes);

    return cast(typeof(return)) functionBytes.ptr;
}

void main()
{
    import std.stdio;

    auto context = 42;

    void del(string s)
    {
        writeln(s);
        writeln(context);
    }

    auto f = delegate2function(&del);
    f("I am a pretty function");
}

Windows 32 ビットおよび Linux 64 ビットでテスト済み。

于 2011-12-28T13:08:57.710 に答える
1

非常に移植性の低い解決策の1つは、呼び出しをラップする関数を動的に作成することです。これを行うには、次のような関数を記述します。

extern(C) RetType TestFn(Arg arg /* and any others */) {
   Class c = cast(Class)(0xDEAD_BEEF);
   return c.Method(arg);
}

次に、この関数を最適化されていないPICとしてコンパイルし、逆コンパイルして、必要なものにマッシュアップできるバイトシーケンスを見つけることができます。最終結果は、関数ポインターを返す方法を持ち、構築voidされると、上記の手順で見つけたバイトを内部配列に入力し、問題のオブジェクトを適切な場所に突き刺すタイプ（おそらく構造体）になります。

もう少し高度なソリューションでは、デリゲートにオブジェクトとメソッドポインターの両方を設定して、両方をコンストラクターに提供できるようにします。さらに高度なソリューションでは、型をテンプレート化し、CおよびDの呼び出し規約の知識を利用して、引数転送コードを動的に生成します。

于 2011-12-28T05:29:47.573 に答える
1

SetWindowLongthisを使用して、ウィンドウ自体に格納するのはどうですか?

于 2011-12-28T12:48:54.530 に答える