3

そのテーブルのすべてのフィールド名を取得し、それらを配列に格納し、その配列を別のSQLクエリのfetchrowと組み合わせて使用​​して、それらのフィールドにデータを表示するサブにテーブル名を渡そうとしています。これが私が今持っているコードです:

パラメータとしてテーブル名を使用したサブ呼び出しの例:

shamoo("reqhead_rec");
shamoo("approv_rec");
shamoo("denial_rec");

シャモー サブ:

sub shamoo
{
    my $table = shift;
    print uc($table)."\n=====================================\n";

    #takes arg (table name) and stores all the field names into an array
    $STMT = <<EOF;
    select first 1 * from $table
    EOF

    my $sth = $db1->prepare($STMT);$sth->execute;

    my ($i, @field);
    my $columns = $sth->{NAME_lc};
    while (my $row = $sth->fetch){for $i (0 .. $#$row){$field[$i] = $columns->[$i];}}

    $STMT = <<EOF;
    select * from $table where frm = '$frm' and req_no = $req_no
    EOF
    $sth = $db1->prepare($STMT);$sth->execute;
    $i=0;
    while ($i!=scalar(@field))
    {
    #need code for in here...
    }
}

これを明示的に定義する必要のないものに変える方法を探しています.... 

my ($frm, $req_no, $auth_id, $alt_auth_id, $id_acct, $seq_no, $id, $appr_stat, $add_date, $approve_date, $approve_time, $prim);
while(($frm, $req_no, $auth_id, $alt_auth_id, $id_acct, $seq_no, $id, $appr_stat, $add_date, $approve_date, $approve_time, $prim) = $sth->fetchrow_array())
4

2 に答える 2

15

fetchrow_hashref を使用します。

sub shamoo {
    my ($dbh, $frm, $req_no, $table) = @_;

    print uc($table), "\n", "=" x 36, "\n";

    #takes arg (table name) and stores all the field names into an array
    my $sth = $dbh->prepare(
        "select * from $table where frm = ? and req_no = ?"
    );

    $sth->execute($frm, $req_no);

    my $i = 1;
    while (my $row = $sth->fetchrow_hashref) {
        print "row ", $i++, "\n";
        for my $col (keys %$row) {
            print "\t$col is $row->{$col}\n";
        }
    }
}

データベースハンドルを作成するときに、またはに設定することもFetchHashKeyNameできます。"NAME_lc""NAME_uc"

my $dbh = DBI->connect(
    $dsn,
    $user,
    $pass,
    {
        ChopBlanks       => 1,
        AutoCommit       => 1,
        PrintError       => 0,
        RaiseError       => 1,
        FetchHashKeyName => "NAME_lc",
    }
) or die DBI->errstr;
于 2009-05-15T15:52:09.163 に答える
2

この方法が空のテーブルで機能するかどうか疑問に思います。

列のメタデータを取得する最も安全な方法は、返された hashref (存在しない可能性があります) のキーを調べるのではなく、ルールに従って、DBI が提供する $sth 自体の属性を使用することです。

$sth->{NAME}->[i]
$sth->{NAME_uc}->[i]
$sth->{NAME_lc}->[i]

詳細については、DBI man ページの Metadata セクションを参照してください。

于 2009-05-15T17:58:08.613 に答える