1

Wifly ライブラリを使用して TCP 経由で送信されるシリアル コマンドを常にチェックする Arduino に次のコードがあります。

次のコードは、シリアル経由で送信されたときに、次のように文字列を分割します。

{power,tv}

それに応じてこれらのプロパティを設定します。

char command[32];
char value[32];

sendCommand(command, value);次に、以下のループで設定されたプロパティに基づいて特定のメソッドを実行します。

これは、Wifly ライブラリを使用すると問題なく機能することに注意してください。

void loop() {
  Client client = server.available();

  if (client) {

    boolean start_data = false;
    boolean next = false;

    char command[32];
    char value[32];
    int index = 0;

    while (client.connected()) {

      if (client.available()) {
        char c = client.read();
        Serial.print(c);

        if (c == '}') {
          break;
        }

        if(start_data == true) {

          if(c != ',') {

            if(next)
              value[index] = c;
            else
              command[index] = c;

            index++;
          } else {
            next = true;
            command[index] = '\0';
            index = 0;
          }

        }

        if (c == '{') {
          start_data = true;
        }

      }

    }

    value[index] = '\0';

    client.flush();
    client.stop();

    sendCommand(command,value);
  }

}

WiFi を使用する代わりに、いくつかの Xbee モジュールを購入しました。基本的に、シリアルバイトも送信できます。唯一の問題は、もうループがないことを考えると、ループを処理する方法がよくわからないことですwhile(client.connected())。その代わりに、うまくいくと考えて使用しましたが、何らかの理由でプロパティをwhile(Serial.available())設定しません。value

わかりますcommandが、わかりませんvalue。

また、上記のループが私が求めていることを実行するための最良の方法であるかどうかもわかりません. :)

これが私の新しいループです。これは、何らかの理由commandではなく、返されるだけです。value

void loop() {

  // if there are bytes waiting on the serial port
  if (Serial.available()) { 
    boolean start_data = false;
    boolean next = false;

    char command[32];
    char value[32];
    int index = 0;

    while (Serial.available()) {
      char c = Serial.read();
      Serial.print(c);

      if (c == '}') {
        break;
      }

      if(start_data == true) {
        if(c != ',') {

          if(next)
            value[index] = c;
          else
            command[index] = c;

          index++;
        } else {
          next = true;
          command[index] = '\0';
          index = 0;
        }

      }

      if (c == '{') {
        start_data = true;
      }

    }

    value[index] = '\0';

    sendCommand(command,value);

  }

}

以下が新しいループで動作する場合、私はとても幸せです!

void sendCommand(char *command, char *value) {
 // do something wonderful with command and value!
}
4

2 に答える 2

1

次のコードを使用して動作するようにしました。

#define SOP '{'
#define EOP '}'

bool started = false;
bool ended = false;

char inData[80];
byte index;

void setup()
{
   Serial.begin(9600);
   // Other stuff...
}

void loop()
{
  // Read all serial data available, as fast as possible
  while(Serial.available() > 0)
  {
    char inChar = Serial.read();
    if(inChar == SOP)
    {
       index = 0;
       inData[index] = '\0';
       started = true;
       ended = false;
    }
    else if(inChar == EOP)
    {
       ended = true;
       break;
    }
    else
    {
      if(index < 79)
      {
        inData[index] = inChar;
        index++;
        inData[index] = '\0';
      }
    }
  }

  // We are here either because all pending serial
  // data has been read OR because an end of
  // packet marker arrived. Which is it?
  if(started && ended)
  {
    // The end of packet marker arrived. Process the packet
    char *cmd = strtok(inData, ",");
    if(cmd)
    {
       char *val = strtok(NULL, ",");
       if(val)
       {
          sendCommand(cmd, val);
       }
    } 

    // Reset for the next packet
    started = false;
    ended = false;
    index = 0;
    inData[index] = '\0';
  }
}
于 2012-01-14T13:30:16.590 に答える
-2

次のような構造を変更します。

while( c != '}') {
     if (Serial.available()) { 
          .
          .
          .
     }
}

シリアル文字は、ループよりも大幅に遅く受信されます。

于 2012-01-13T17:47:20.260 に答える