1

現在、Canvas.Pixels[]プロパティをループし、キャンバス上の各ピクセルを読み取って、赤/青のバイトを交換します (特定の理由により)。ただし、画像ごとに平均 2 秒かかり、8,000 枚以上の画像を変換する必要があります (一晩で)。の方法を使用してこれをはるかに高速に実行できることは理解してScanLineいますが、それについては何も知りませんScanLine。これは、私が慣れているよりもはるかに低いレベルのコーディングです。これを達成するための最速の方法は何ですか? これが実行されるまでしばらく待ちますが、その時間を半分またはそれ以上に分割できれば幸いです.

今、これは私が使用する手順です：

procedure SwapBytes(var Bmp: TBitmap);
var
  X, Y: Integer;
  R, G, B: Byte;
  C: TColor;
begin
  for Y := 0 to Bmp.Height - 1 do begin
    for X := 0 to Bmp.Width - 1 do begin
      C:= Bmp.Canvas.Pixels[X,Y];
      R:= GetRValue(C);
      G:= GetGValue(C);
      B:= GetBValue(C);
      Bmp.Canvas.Pixels[X,Y]:= RGB(B, G, R)
    end;
  end;
end;

追加された注: 8,000 を超える画像の最初の変換は、これが必要な理由の最初のステップです。ただし、必要に応じて、ソフトウェアで同じことを使用して、その場で画像を自動的に変換します。したがって、これをクライアントに配布できないため、サードパーティのコンバーターは機能しません。

4

1 に答える 1

9

私は次のようなことを試みます。このバージョンは24ビットビットマップ専用です。

procedure SwapRedBluePixels(ABitmap: TBitmap);
var
  X: Integer;
  Y: Integer;
  Red: Byte;
  Pixel: PRGBTriple;
begin
  // check for the bit depth, it must be 24-bit if you use PRGBTriple pointer
  // for line scan; if it wouldn't the iterated line pointers would point to 
  // another place in the memory
  if ABitmap.PixelFormat <> pf24bit then
  begin
    ShowMessage('Your bitmap has color depth different from 24-bit');
    Exit;
  end;
  // iterate through the image vertically
  for Y := 0 to (ABitmap.Height - 1) do
  begin
    // access the line of pixels and get the pointer to the first pixel of 
    // that line
    Pixel := ABitmap.ScanLine[Y];
    // iterate through the scanned line pixels horizontally
    for X := 0 to (ABitmap.Width - 1) do
    begin
      // store the pixel's red channel value
      Red := Pixel.rgbtRed;
      // modify the pixel's red channel value
      Pixel.rgbtRed := Pixel.rgbtBlue;
      // modify the pixel's blue channel value
      Pixel.rgbtBlue := Red;
      // increment to get the next pixel pointer of the scanned line
      Inc(Pixel);
    end;
  end;
end;

アップデート2：

このバージョンは、24ビットおよび32ビットビットマップ用です。

procedure SwapRedBluePixels(ABitmap: TBitmap);
var
  X: Integer;
  Y: Integer;
  Red: Byte;
  Size: Integer;
  Pixels: PByteArray;
begin
  // check the color depth and set the size of the pixel arrangement
  case ABitmap.PixelFormat of
    pf24bit: Size := SizeOf(TRGBTriple);
    pf32bit: Size := SizeOf(TRGBQuad);
  else
    // if the image is not 24-bit or 32-bit go away
    begin
      ShowMessage('Your bitmap has unsupported color depth!');
      Exit;
    end;
  end;

  // iterate through the image vertically
  for Y := 0 to (ABitmap.Height - 1) do
  begin
    // access the line of pixels and get the pointer to the first pixel of
    // that line
    Pixels := ABitmap.ScanLine[Y];
    // iterate through the scanned line pixels horizontally
    // for 24-bit images the pixels are stored like
    // B -> G -> R -> B -> G -> R etc.
    // for 32-bit images the pixels are stored like
    // B -> G -> R -> A -> B -> G -> R -> A etc.
    // so we can simply use e.g. byte array and iterate through
    // it, if we have 24-bit image, we have to read each element,
    // if 32-bit we have to skip the alpha (reserved) channel
    for X := 0 to (ABitmap.Width - 1) do
    begin
      // store the pixel's red channel value
      Red := Pixels^[(X * Size) + 2];
      // modify the pixel's red channel value
      Pixels^[(X * Size) + 2] := Pixels^[(X * Size)];
      // modify the pixel's blue channel value
      Pixels^[(X * Size)] := Red;
    end;
  end;
end;
于 2012-01-19T19:32:50.210 に答える