2

単純な XML ファイルがあるとします。

<data>
  <text>Hello world!&lt;br&gt;Nice to see you all!&lt;br&gt;Goodbye!</text>
</data>

&lt;br&gt;今、すべての文字列を文字列に置き換えたい&#10;ので、結果は次のようになります。

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

どうすればいいですか？

XSL 置換機能は簡単に実装できます (例: http://geekswithblogs.net/Erik/archive/2008/04/01/120915.aspx ) が、難しいのは XSL トランスフォーマーにこれらの&#10;文字列を出力させることです。非表示の通常の改行を取得するか、&amp;#10;

完璧な答えは、トリックを行う XSL テンプレートです。

4

1 に答える 1

1

使用する：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/data">
    <transformed>
      <text>
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="text" />
          <xsl:with-param name="replace">&lt;br&gt;</xsl:with-param>
          <xsl:with-param name="by">&amp;#10;</xsl:with-param>
        </xsl:call-template>
      </text>
    </transformed>
  </xsl:template>

  <xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
      <xsl:when test="contains($text, $replace)">
        <xsl:value-of select="substring-before($text, $replace)" />
        <xsl:value-of select="$by" disable-output-escaping="yes" />
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="substring-after($text,$replace)" />
          <xsl:with-param name="replace" select="$replace" />
          <xsl:with-param name="by" select="$by" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

出力：

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

注意:

disable-output-escaping属性を設定yes

于 2012-01-31T13:10:39.740 に答える