3

WM_COPYDATA によってアプリケーション間で文字列メッセージを送信するコンポーネントを作成しようとしています。WM_COPYDATA をトラップしたいのですが、うまくいきません:

TMyMessage = class(TComponent)
private
{ Private declarations } 
…
protected
{ Protected declarations }
…
procedure WMCopyData(var Msg : TMessage); message WM_COPYDATA;
…
end;

Google をよく検索すると、wndproc を使用していくつかの参照が見つかりました。試してみましたが、うまくいきません。

TMyMessage = class(TComponent)
…
protected
{ Protected declarations }
…
procedure WMCopyData(var Msg : TMessage); message WM_COPYDATA;
procedure WndProc(var Msg: TMessage);
…
end;
…
procedure TMyMessage.WndProc(var Msg: TMessage);
begin
  //inherited;
  if Msg.Msg = WM_COPYDATA then
    WMCopyData(Msg);
end;

助けてください、何が問題なのですか?

4

3 に答える 3

3

ここまでは問題ありませんが、最初にメッセージがコンポーネントに配信されるように手配する必要があります。これには、ウィンドウ ハンドルが必要です。コンポーネントのメソッドを呼び出しAllocateHWndて渡します。WndProcコンポーネントが破棄されるときに破棄する必要があるウィンドウ ハンドルを返します。

constructor TMyMessage.Create(AOwner: TComponent);
begin
  inhreited;
  FHandle := AllocateHWnd(WndProc);
end;

destructor TMyMessage.Destroy;
begin
  DeallocateHWnd(FHandle);
  inherited;
end;

各メッセージを直接テストするのではなく、自分でテストすることができTObjectます。そのためのDispatchメソッドです。レコードを渡すとTMessage、対応するメッセージ ハンドラー メソッドが検索され、呼び出されます。そのようなハンドラーがない場合は、DefaultHandler代わりに呼び出します。を呼び出すことができるオーバーライドDefWindowProc。

procedure TMyMessage.WndProc(var Message);
begin
  Dispatch(Message);
end;

procedure TMyMessage.DefaultHandler(var Message);
begin
  TMessage(Message).Result := DefWindowProc(Self.Handle, TMessage(Message).Msg,
    TMessage(Message).WParam, TMessage(Message).LParam);
end;
于 2012-02-01T14:52:36.990 に答える
1

私はそれをこのようにしました：

スレッドで実行されている私のWebモジュールは、メインフォームのメモに文字列を送信する必要があります。FReceiverFromWSはTHandleです

作成時：

procedure TWebModuleWebServices.WebModuleCreate(Sender: TObject);
begin
   FReceiverFromWS := FindWindow(PChar('TFormWebServices'),PChar(cFormCaption + FormWebServices.Instance)); // Search by class name and caption of receiving form
   // ==> you could to that without form caption, but I need to distinguish between running services
   if FReceiverFromWS = 0 then
      begin
         Assert(False,'CopyData receiver NOT found!');  // Probably TFormWebServices not yet created
         Exit;
      end;
end;

メッセージを送信するには：

procedure TWebModuleWebServices.SendAMessage(Msg: String);
// Windows will guarantee that the data sent in the COPYDATASTRUCT will exist until     after the WM_COPYDATA message
// has been carried out. As such, we must use SendMessage() to send a WM_COPYDATA message. We cannot use PostMessage().
var
   lCopyDataStruct: TCopyDataStruct;
begin
   lCopyDataStruct.dwData := 0;
   lCopyDataStruct.cbData := 1 + Length(Msg);
   lCopyDataStruct.lpData := PChar(Msg);
   SendMessage(FReceiverFromWS, WM_COPYDATA, wParam(FReceiverFromWS), lParam(@lCopyDataStruct));
end;

メインフォームでは、パブリックメソッド

プロシージャWMCopyData（var Msg：TWMCopyData）; メッセージWM_COPYDATA;

は：

procedure TFormWebServices.WMCopyData(var Msg: TWMCopyData);
var
   i : integer;
   s : string;
begin
   i := Msg.CopyDataStruct.dwData;
   case i of
      0: begin  // Message to display
            s := String(PChar(Msg.CopyDataStruct.lpData));
            AddMemoLine(s);
         end;
      1: begin  // Statistical data
            s := String(PChar(Msg.CopyDataStruct.lpData));
            FrmWebServiceStats.CollectStats(s);
         end;
   end;
end;

（ご覧のとおり、私は実際にdwDataを使用してメッセージの種類を通知し、これらを異なる方法で処理します）

于 2012-02-02T15:45:58.373 に答える
1

あなたの問題はTComponent、ウィンドウ化されたコンポーネントではないことです。WM_COPYDATAは Windows メッセージであり、ウィンドウ プロシージャを介して配信されます。したがって、ウィンドウハンドルが必要です。これらのいずれかを取得するために使用AllocateHwndします。

type
  TMyComponent = class(TComponent)
  private
    FWindowHandle: HWND;
    procedure WndProc(var Msg: TMessage);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;

constructor TMyComponent.Create(AOwner: TComponent);
begin
  inherited;
  FWindowHandle := AllocateHwnd(WndProc);
end;

destructor TMyComponent.Destroy;
begin
  DeallocateHwnd(FWindowHandle);
  inherited;
end;

procedure TMyComponent.WndProc(var Msg: TMessage);
begin
  if Msg.Msg=WM_COPYDATA then
    //do domething
  else
    Msg.Result := DefWindowProc(FWindowHandle, Msg.Msg, Msg.WParam, Msg.LParam);
end;

メッセージを送信しているものは何でも、ウィンドウ ハンドルを取得する方法を見つける必要があります。

于 2012-02-01T14:51:54.383 に答える