1

私はそのようなxmlを持っています:

<root>
  <element1>
     <doc>2</doc>
  </element1>
  <doc>1</doc>
</root>

ルート要素 (値 = 1) の後の最初の子レベルで要素を取得したい。ノードリスト（xmldom apiのpl/sqlバージョン）を介して行う場合：

nl := getElementsByTagName(rootnode,'doc');
len := xmldom.getLength(nl);
IF LEN>0 THEN
    N:=xmldom.item(nl, 0);
END IF;
RETURN N;

リストの最初の要素は、値 = 2 の要素になります。要素をループせずに、最初の子レベルの子ノードのみを処理するにはどうすればよいですか?

4

2 に答える 2

2

DBMS_XMLDOMでは、 GETCHILDRENBYTAGNAMEを使用します:

declare
  xml constant xmltype := xmltype(
'<root>
  <element1>
     <doc>2 - two</doc>
  </element1>
  <doc>1 - one</doc>
</root>'
);
  doc constant dbms_xmldom.domdocument := dbms_xmldom.newdomdocument(xml);

  root_elem constant dbms_xmldom.domelement :=
    dbms_xmldom.getdocumentelement(doc);

  doc_nodes constant dbms_xmldom.domnodelist :=
    dbms_xmldom.getchildrenbytagname(root_elem, 'doc');
begin
  declare
    last_index constant pls_integer := dbms_xmldom.getlength(doc_nodes) - 1;
    node dbms_xmldom.domnode;
    text_node dbms_xmldom.domnode;
  begin
    for i in 0 .. last_index loop
      node := dbms_xmldom.item(doc_nodes, i);
      text_node := dbms_xmldom.getfirstchild(node);
      dbms_output.put_line('i = ' || i ||
                           ' name = ' || dbms_xmldom.getnodename(node) ||
                           ' type = ' || dbms_xmldom.getnodetype(node) ||
                           ' text = ' || dbms_xmldom.getnodevalue(text_node));
    end loop;
  end;
end;
/

出力：

SQL> @so24
i = 0 name = doc type = 1 text = 1 - one

PL/SQL procedure successfully completed.

SQL>
于 2012-02-03T22:45:08.297 に答える
0

xslprocessorパッケージを使用してから、XPathを使用して適切なノードを見つけることができます。 

nl := xslprocessor.selectnodes(rootnode, 'root/doc');
len := xmldom.getLength(nl);
IF LEN>0 THEN
    N:=xmldom.item(nl, 0);
END IF;
RETURN N;
于 2012-02-06T09:17:30.030 に答える