0

私はフリーマインドで編集している非常に単純な分類法を持っており、それをサンバーストの視覚化としてプロトビスで視覚化したいと考えています。分類の深さは不明です。

私は、xslスクリプト機能を介したFreemindのエクスポートで使用できるXLST変換を構築する試みを作成しました-サンバーストを生成するためにProtovisが必要とする正確なJSON形式でデータを出力します-javascriptでそれ以上の変換は必要ありません。

私が探している出力JSON形式の例はここにあります：http： //mbostock.github.com/protovis/ex/sunburst.html

事実上、freemind.mmファイル形式が入力です。

スタイラススタジオでアルファコード（以下に表示）を実行すると、json形式（フォーマットが正しくないが合法的なようです）が構築され、スタイラススタジオから生成された出力を手動で.jsファイルに直接保存するとprotovisokにフィードされます。何らかの理由で、Freemindはこのコードを使用してデータをエクスポートしていないようですが...

足りないものはありますか？助けていただければ幸いです。

どうもありがとう、アンドリュー

=========== UPDATE =============

コードを修正しました。問題は、私のxslの一部がfreemindで使用されるxsltエンジンでサポートされていないことでした。コードを修正し、リベラルなライセンスの下でgithubに移動して、ここから削除しました。

アダプターはここから入手できます： https ：//github.com/minkymorgan/Freemind2JSON#readme

  • アンドリュー
4

2 に答える 2

0

これが私の試みです。あなたのバージョンに基づいて、さらにいくつかの機能を追加しました。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

    <xsl:template match="/map">
        <xsl:text>var Map = {
</xsl:text>
        <xsl:apply-templates select="node">
            <xsl:with-param name="indent">
                <xsl:text>    </xsl:text>
            </xsl:with-param>
        </xsl:apply-templates>
        <xsl:text>
};
</xsl:text>
    </xsl:template>

    <xsl:template match="node">
        <xsl:param name="indent"/>
        <xsl:if test="position() != 1">
            <xsl:text>,
</xsl:text>
        </xsl:if>
        <xsl:value-of select="$indent"/>
        <xsl:text>"</xsl:text>
        <xsl:call-template name="escape-javascript">
            <xsl:with-param name="string"
                select="descendant-or-self::node/@TEXT"/>
        </xsl:call-template>
        <xsl:text>": </xsl:text>
        <xsl:choose>
            <xsl:when test="node">
                <xsl:text>{
</xsl:text>
                <xsl:apply-templates select="node">
                    <xsl:with-param name="indent">
                        <xsl:value-of select="$indent"/>
                        <xsl:text>    </xsl:text>
                    </xsl:with-param>
                </xsl:apply-templates>
                <xsl:text>
</xsl:text>
                <xsl:value-of select="$indent"/>
                <xsl:text>}</xsl:text>
            </xsl:when>
            <xsl:otherwise>
                <xsl:text>10</xsl:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <!--
        Javascript string escape template by Jeni Tennison
        Source: http://holytshirt.blogspot.com/2008/06/xslt-javascript-escaping.html
        Author page: http://www.jenitennison.com/
    -->
    <xsl:template name="escape-javascript">
        <xsl:param name="string" />
        <xsl:choose>
            <xsl:when test='contains($string, "&apos;")'>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select='substring-before($string, "&apos;")' />
                </xsl:call-template>
                <xsl:text>\'</xsl:text>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select='substring-after($string, "&apos;")' />
                </xsl:call-template>
            </xsl:when>
            <xsl:when test="contains($string, '&#xA;')">
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select="substring-before($string, '&#xA;')" />
                </xsl:call-template>
                <xsl:text>\n</xsl:text>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select="substring-after($string, '&#xA;')" />
                </xsl:call-template>
            </xsl:when>
            <xsl:when test="contains($string, '\')">
                <xsl:value-of select="substring-before($string, '\')" />
                <xsl:text>\\</xsl:text>
                <xsl:call-template name="escape-javascript">
                    <xsl:with-param name="string"
                        select="substring-after($string, '\')" />
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise><xsl:value-of select="$string" /></xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Freemind テスト ファイルで実行すると、次の出力が生成されます。

var Map = {
    "Notetest": {
        "Notetest": 10,
        "This is a node": {
            "with a linbreak \n subnode": 10,
            "and another subnode": 10,
            "and some folded subnodes": {
                "fold1": 10,
                "fold2": 10,
                "fold3": 10
            }
        },
        "Attributes": 10
    }
};
于 2012-02-04T18:50:03.043 に答える
0

参考までに... FreeMind を JSON に変換するための XSLT スクリプトをプッシュしました。私のスクリプトはもう少し単純で、まだ Javascript エスケープをサポートしていません。

また、Protovis で使用するように設計されていません。

于 2012-12-01T16:36:51.603 に答える