3

antlr 2.7.6を使用して単純な式パーサーを作成しようとしていますが、コンパイル中に非決定性の警告が表示されます。生成されたJavaソースは私が望むとおりに機能しているようですが、この警告を抑制することが可能かどうか、または文法で何か間違ったことをしているのかどうかを知りたいです。

パーサーは、この古いバージョンのantlrにすでに依存しているプロジェクトで使用されるため、3.4にアップグレードすることはおそらくオプションではありません。文法自体は、この回答の文法と似ています。

コンパイル中の出力は次のとおりです。

Using Antlr grammar: expr.g
ANTLR Parser Generator   Version 2.7.6 (2005-12-22)   1989-2005
expr.g:15: warning:nondeterminism upon
expr.g:15:     k==1:OR
expr.g:15:     between alt 1 and exit branch of block
expr.g:19: warning:nondeterminism upon
expr.g:19:     k==1:AND
expr.g:19:     between alt 1 and exit branch of block

そして、ここに問題を示す簡略化された文法があります：

header {
package net.jhorstmann.i18n.tools;

import net.jhorstmann.i18n.tools.*;
import net.jhorstmann.i18n.tools.expr.*;
}

class ExprParser extends Parser;

expression returns [Expression r = null]
    : r=or_expr
    ;

or_expr returns [Expression r = null] { Expression e = null; }
    : r=and_expr   (OR e=and_expr   { r = new OrExpression(r, e); })*
    ;

and_expr returns [Expression r = null] { Expression e = null; }
    : r=prim_expr  (AND e=prim_expr { r = new AndExpression(r, e); })*
    ;

prim_expr returns [Expression r = null] { Expression e = null; }
    : b:BOOL                   { r = new ConstantExpression(Integer.parseInt(b.getText())); }
    | NOT e=expression         { r = new NotExpression(e); }
    | OPEN e=expression CLOSE  { r = e; }
    ;

class ExprLexer extends Lexer;

options {
    k=2;
}

WS      : (' ' | '\t')+ { $setType(Token.SKIP); };
BOOL    : '0' | '1';
NOT     : '!';
OPEN    : '(';
CLOSE   : ')';
OR      : '|' '|';
AND     : '&' '&';
4

1 に答える 1

2

奇妙なことに、ANTLR3はそのような文法に問題はありません。

「ブロックの終了ブランチ」に関する警告があるため、ファイルの終わりトークン（）を使用してエントリルールを固定してみてください。EOF

expression returns [Expression r = null]
    : r=or_expr EOF
    ;

編集

次のような単項否定式を含めます。

expression
    : or_expr EOF
    ;

or_expr
    : and_expr (OR and_expr)*
    ;

and_expr
    : unary_expr (AND unary_expr)*
    ;

unary_expr
    : NOT prim_expr
    | prim_expr
    ;

prim_expr
    : BOOL
    | OPEN or_expr CLOSE
    ;
于 2012-02-19T10:16:14.160 に答える