92

現在処理されている要素の数を反映する xsl:for-each ループ内のカウンターを取得する方法。
たとえば、私のソース XML は

<books>
    <book>
        <title>The Unbearable Lightness of Being </title>
    </book>
    <book>
        <title>Narcissus and Goldmund</title>
    </book>
    <book>
        <title>Choke</title>
    </book>
</books>

私が取得したいものは次のとおりです。

<newBooks>
    <newBook>
        <countNo>1</countNo>
        <title>The Unbearable Lightness of Being </title>
    </newBook>
    <newBook>
        <countNo>2</countNo>
        <title>Narcissus and Goldmund</title>
    </newBook>
    <newBook>
        <countNo>3</countNo>
        <title>Choke</title>
    </newBook>
</newBooks>

変更する XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <newBooks>
            <xsl:for-each select="books/book">
                <newBook>
                    <countNo>???</countNo>
                    <title>
                        <xsl:value-of select="title"/>
                    </title>
                </newBook>
            </xsl:for-each>
        </newBooks>
    </xsl:template>
</xsl:stylesheet>

問題は、???の代わりに何を入れるかです。標準のキーワードはありますか、それとも単に変数を宣言してループ内でインクリメントする必要がありますか?

質問がかなり長いので、おそらく1行または1語の回答を期待する必要があります:)

4

5 に答える 5

148

position(). 例えば：

<countNo><xsl:value-of select="position()" /></countNo>
于 2008-09-18T15:25:19.063 に答える
13

<xsl:number format="1. "/><xsl:value-of select="."/><xsl:text>???の所に挿入してみてください。

「1.」に注意してください - これは数値形式です。詳細：こちら

于 2008-09-18T15:26:27.687 に答える
10

試す：

<xsl:value-of select="count(preceding-sibling::*) + 1" />

編集- そこで脳がフリーズしました。position() の方が簡単です!

于 2008-09-18T15:28:11.723 に答える
8

また、Postion（）で条件ステートメントを実行することもできます。これは、多くのシナリオで非常に役立ちます。

たとえば。

 <xsl:if test="(position( )) = 1">
     //Show header only once
    </xsl:if>
于 2010-11-20T01:05:46.900 に答える
5 
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:template match="/">
        <newBooks>
                <xsl:for-each select="books/book">
                        <newBook>
                                <countNo><xsl:value-of select="position()"/></countNo>
                                <title>
                                        <xsl:value-of select="title"/>
                                </title>
                        </newBook>
                </xsl:for-each>
        </newBooks>
    </xsl:template>
</xsl:stylesheet>
于 2008-09-18T15:26:25.627 に答える