vba - VBA(Excel)でミリ秒単位でDateDiff-Valueを取得するには?

Question

2 つのタイムスタンプの差をミリ秒単位で計算する必要があります。残念ながら、VBA の DateDiff 関数はこの精度を提供しません。回避策はありますか?

Answer 1

ここで説明する方法を次のように使用できます。

という名前の新しいクラス モジュールを作成します。クラス モジュールStopWatch に次のコードを追加しStopWatchます。

Private mlngStart As Long
Private Declare Function GetTickCount Lib "kernel32" () As Long

Public Sub StartTimer()
    mlngStart = GetTickCount
End Sub

Public Function EndTimer() As Long
    EndTimer = (GetTickCount - mlngStart)
End Function

コードは次のように使用します。

Dim sw as StopWatch
Set sw = New StopWatch
sw.StartTimer

' Do whatever you want to time here

Debug.Print "That took: " & sw.EndTimer & "milliseconds"

他の方法では VBA タイマー関数の使用について説明していますが、これは 100 分の 1 秒 (センチ秒) までしか正確ではありません。

Answer 2

センチ秒単位の経過時間が必要な場合は、TickCount API は必要ありません。すべての Office 製品に存在する VBA.Timer メソッドを使用できます。

Public Sub TestHarness()
    Dim fTimeStart As Single
    Dim fTimeEnd As Single
    fTimeStart = Timer
    SomeProcedure
    fTimeEnd = Timer
    Debug.Print Format$((fTimeEnd - fTimeStart) * 100!, "0.00 "" Centiseconds Elapsed""")
End Sub

Public Sub SomeProcedure()
    Dim i As Long, r As Double
    For i = 0& To 10000000
        r = Rnd
    Next
End Sub

Answer 3

マイクロ秒の場合は、GetTickCount と Performance Counter が必要です。ミリ秒の場合は、次のようなものを使用できます。

'at the bigining of the module
Private Type SYSTEMTIME  
        wYear As Integer  
        wMonth As Integer  
        wDayOfWeek As Integer  
        wDay As Integer  
        wHour As Integer  
        wMinute As Integer  
        wSecond As Integer  
        wMilliseconds As Integer  
End Type  

Private Declare Sub GetLocalTime Lib "kernel32" (lpSystemTime As SYSTEMTIME)  


'In the Function where you need find diff
Dim sSysTime As SYSTEMTIME
Dim iStartSec As Long, iCurrentSec As Long    

GetLocalTime sSysTime
iStartSec = CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'do your stuff spending few milliseconds
GetLocalTime sSysTime ' get the new time
iCurrentSec=CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'Different between iStartSec and iCurrentSec will give you diff in MilliSecs

Answer 4

=NOW()セルで計算された数式を使用することもできます。

Dim ws As Worksheet
Set ws = Sheet1

 ws.Range("a1").formula = "=now()"
 ws.Range("a1").numberFormat = "dd/mm/yyyy h:mm:ss.000"
 Application.Wait Now() + TimeSerial(0, 0, 1)
 ws.Range("a2").formula = "=now()"
 ws.Range("a2").numberFormat = "dd/mm/yyyy h:mm:ss.000"
 ws.Range("a3").formula = "=a2-a1"
 ws.Range("a3").numberFormat = "h:mm:ss.000"
 var diff as double
 diff = ws.Range("a3")

Answer 5

AdamRalph ( GetTickCount()) によって記述されたメソッドに加えて、次のことができます。

• QueryPerformanceCounter()およびQueryPerformanceFrequency()API 関数の使用
  VBA コードの実行時間をどのようにテストしますか?
• または、Win32 API (VBScript など) にアクセスできない環境の場合は、http:
  //ccrp.mvps.org/ (「ハイパフォーマンス タイマー」インストール可能 COM オブジェクトのダウンロード セクションを確認してください。これらは無料です。)