7

私はrokuおよびroku固有の言語（BasicScript）を使用するのは非常に新しいです。チャネルを取得するには、サーバーに対してAPI呼び出しを行う必要があります。rokuでそれを行う方法がわかりません。提案してください。

4

2 に答える 2

10

SDK に含まれているコード ライブラリの構文に依存せずに直接実行する方法を次に示します。

ブロッキング方法 (URL が取得されるまで、すべてのプログラムの実行が停止します):

url="http://myserver.com/anExampleQuery?getmydata&apikey=AX5GZP5LL45D987D0&format=XML"
xfer=createobject("roURLTransfer")
xfer.seturl(url)
data=xfer.gettostring()

データを待っている間に他のことを行うことができるノンブロッキングメソッド：

url="http://myserver.com/anExampleQuery?getmydata&apikey=AX5GZP5LL45D987D0&format=XML"
xfer=createobject("roURLTransfer")
xfer.seturl(url)
port=createobject("roMessagePort")
xfer.setport(port)
timer=createobject("roTimeSpan")
timer.mark()
xfer.asyncgettostring()
while true    
    msg=wait(100,port) '100 millisecond pause
    if type(msg)="roUrlEvent" then

        if msg.getresponsecode()=200 then
            data=msg.getstring()
            headers=msg.getresponseheadersarray()
            exit while
        else
            xfer.asynccancel()
        end if
    else
        print "do something useful while we wait for data"   
    end if
    if timer.totalmilliseconds() > 500 then
        ?"timeout exceeded"
        exit while
    end if
end while
print "***************HEADERS******************"
for each header in headers
print header
end for
print "***************DATA*********************"
print data
print "****************************************"
于 2012-05-17T05:11:28.507 に答える
0 
http=NewHttp("http://server address")
rsp = http.GetToStringWithRetry()
print rsp 'To check the response text from server
于 2012-02-27T04:09:42.393 に答える