1

行列またはベクトルの特定の要素を選択したいのですが、0より大きいとしましょう.1つのオプションは、行列/ベクトルのすべての要素をループすることですが、これを達成するためのより良い方法があるかどうか疑問に思います(Rのように、どの状態)。私のコードは次のようになります。

matrix.
compute A={1,2,5,6,1,6,0,4,0,3,6,0,2,-3}.
compute b=0.

loop #i=1 to ncol(A).
    do if ( A(1,#i) >0 ).
        compute b={b,a(1,#i)}.
    end if.
end loop.

compute b=b(1,2:ncol(b)).
print b.

end matrix.
4

1 に答える 1

0

必要なインデックスがある場合は、別のサブセット ベクトルでそれらを指定するだけです。

matrix.
compute A={1,2,5,6,1,6,0,4,0,3,6,0,2,-3}.
compute take = {1,2,4}.
print A(take).
end matrix.

これは1 2 6、印刷ステートメントで生成されます。さて、インデックスを取得するのは少し面倒です。1 つの方法は、必要なGRADEインデックスを取得するための順序を提供する、満たす条件の否定で使用することです。次に、条件を満たすことがわかっているインデックスの総数のみを選択します。

matrix.
compute A={1,2,5,6,1,6,0,4,0,3,6,0,2,-3}.

*make sequential index and vector with selection.
compute take = {1:NCOL(A)}.
compute sel = A > 0.

*reording the indices so the selected columns are first.
compute take(GRADE(-1*sel)) = take.

*only taking the indices that meet the selection.
compute take = take(1:RSUM(sel)).

*results.
print A.
print A(take).
end matrix.

これをマクロにまとめて、これを少し簡単にすることができます。ここで動作する例を次に示します。

DEFINE !SelCol (Data = !TOKENS(1)
               /Condition = !TOKENS(1) 
               /Result = !TOKENS(1) )
COMPUTE XKeepX = !UNQUOTE(!Condition).
COMPUTE XIndX = {1:NCOL(!Data)}.
COMPUTE XIndX(GRADE(XKeepX*-1)) = XIndX.
COMPUTE XIndX = XIndX(1:RSUM(XKeepX)).
COMPUTE !Result = !Data(1:NROW(!Data),XIndX).
RELEASE XKeepX.
RELEASE XIndX.
!ENDDEFINE.

MATRIX.
COMPUTE A={1,2,5,6,1,6,0,4,0,3,6,0,2,-3}.
!SelCol Data=A Condition='A>0' Result=ASel.
PRINT ASel.
END MATRIX.

このアプローチは、マトリックスの特定の行の選択にも容易に適用できます。

DEFINE !SelRow (Data = !TOKENS(1)
               /Condition = !TOKENS(1)
               /Result = !TOKENS(1) )
COMPUTE XKeepX = !UNQUOTE(!Condition).
COMPUTE XIndX = {1:NROW(!Data)}.
COMPUTE XIndX(GRADE(XKeepX*-1)) = XIndX.
COMPUTE XIndX = XIndX(1:CSUM(XKeepX)).
COMPUTE !Result = !Data(XIndX,1:NCOL(!Data)).
RELEASE XKeepX.
RELEASE XIndX.
!ENDDEFINE.

これはかなり速いはずです。ほとんどの時間は、条件ステートメントとデータの抽出に費やされます。非常に多数の行または列の場合でも、インデックスのランク付けは非常に簡単です。

于 2014-07-16T20:57:04.600 に答える