3

SQL Server の全文検索機能を特定の方法で使用できるかどうかを確認しようとしています。

私の考えは、次のようなことをすることです: N 個のキーワードを取り、そのキーワードのすべての形式とその同義語を検索します。

私が思いついたのは、次のようなものでした。

SELECT * 
FROM table
WHERE CONTAINS(*, CONTAINS(*,'FORMSOF(THESAURUS,FORMSOF(INFLECTIONAL,"keyword"))')

しかし、このクエリは機能しません。これは可能ですか？私の考えは合理的ですか、それとも私は気が狂っていますか?

4

2 に答える 2

1

次のようなことをしなければならないと思います：

Select * from TABLE
Where 
  CONTAINS(*,'FORMSOF(THESAURUS,"keyword")')
  OR
  CONTAINS(*,'FORMSOF(INFLECTIONAL,"keyword")')

編集

それ以外の場合は、次のように CONTAINS 検索条件を動的に作成する必要がある場合があります。

IF OBJECT_ID('tempdb..#A') IS NOT NULL DROP TABLE #A
IF OBJECT_ID('tempdb..#B') IS NOT NULL DROP TABLE #B

CREATE TABLE #A (pk INT IDENTITY(1,1), word nvarchar(50))
CREATE TABLE #B (word nvarchar(50))

-- load words from thesaurus
INSERT INTO #A (word)
  SELECT display_term 
  FROM sys.dm_fts_parser('FORMSOF (THESAURUS, "mykeyword")',1033,null,0)

DECLARE @cmd NVARCHAR(1000) , @word NVARCHAR(50);
DECLARE @k INT;SET @k = ISNULL((SELECT MAX(pk) FROM #A) , 0 )

-- call INFLECTIONAL for each word
WHILE @k>0
BEGIN
  SELECT @word = word FROM #A WHERE pk = @k
  SET @cmd = 'INSERT INTO #B (word)
    SELECT display_term 
    FROM sys.dm_fts_parser(''FORMSOF (INFLECTIONAL, "' + @word + '")'',1033,null,0)'
  EXEC(@cmd)
  SET @k = @k - 1
END

-- list all words
SELECT * FROM #B

DECLARE @FTString  NVARCHAR(4000);
SET @FTString  = '';

-- build the list of words for CONTAINS
SELECT @FTString  = 
    @FTString + 
  + CASE WHEN @FTString='' 
     THEN '' 
     ELSE ' OR ' 
    END
  + '"'+word+'"'
FROM #B

-- display the CONTAINS condition
SELECT @FTString

-- final search
SELECT * 
FROM dbo.MyTable AS x 
WHERE CONTAINS(*, @FTString)
于 2012-02-27T13:42:08.693 に答える
0

http://arcanecode.com/2008/05/27/using-formsof-in-sql-server-full-text-searching/のFREETEXT(...)代わりに試してみる価値があるかもしれません。CONTAINS(...)

于 2013-02-26T15:54:33.007 に答える