1

私はPerlでParse::RecDescentパーサーを使用していますが、そこから情報を取得するのに最もひどい時間を過ごしているようです。オンラインですぐに入手できる情報には、重要な例がないようです。

コードは次のとおりです。

event_function: object_list ':' event_list ';'
        <defer:
        {       #item is a special character with Parse::Recdescent.
            print Dumper($item{object_list});
            $return = $item[1];
        }
        >
        | object_list ':' ';'
        <defer:
        { 
            print Dumper($item{object_list});
            $return = $item[1];
        }
        >

これが出力です

PS W:\developers\paulnathan\rd_dir> perl parser.pl testfile
$VAR1 = 4;
$VAR1 = 8;
PS W:\developers\paulnathan\rd_dir>

入力ファイルは正しく解析されます。

stuff, stuff2: pre-operation event = {foo1, foo2};

「stuff」、「stuff2」をキーとするハッシュを出力する必要があります。

考え？

編集：

object_list : 
        object ',' object_list
        <defer:
        {

            my $retval = ();
            $retval = ::merge_hash_refs($item[1], $item[3]);

            $return = $retval;
        }
        >
        | object
        <defer:
        { 
            #print Dumper($item{object});
            $return = $item{object};
        }
        >       

    object : 
        '/' /[a-z0-9_][a-z0-9_]*/ '/' '...'
            <defer:
            {
                $::objects->{$item[2]} = "stuff";
                $return = $::objects;
            }
            >
        |  /[a-z0-9_][a-z0-9_]*/
            <defer:
            { 
                $::objects->{$item[1]} = "stuff";
                $return = $::objects;
            }
            >

edit2：念のため、Merge_hash_refs。:-)

#takes two hash references.
sub merge_hash_refs {
    my($ref1, $ref2) = @_;
    my $retref = ();
    while( my ($k, $v) = each %$ref1 ) {
        $retref->{$k} = $v;
    }
    while( my ($k, $v) = each %$ref2 ) {
        $retref->{$k} = $v;
    }

    return $retref;
}
4

2 に答える 2

6

スクリプトにを追加するuse strictと、致命的なエラーが発生します。[呼び出し先]で「厳密な参照」が使用されている間は、文字列（「1」）をハッシュ参照として使用できませんmerge_hash_refs。<defer>ディレクティブによって作成されたクロージャ@itemにより、サブルールによって最終的に返されるハッシュ参照ではなく、プロダクションが一致したときにのコンテンツが発生しているようです。ディレクティブを削除すると、次の<defer>出力が得られます。

$VAR1 = {
          'stuff2' => 'stuff',
          'stuff' => 'stuff'
        };

もちろん、これにはobject、上位レベルのルールが失敗した場合でも（バックトラックを含む）、成功したプロダクションによって$::objectが更新されるという副作用があります。私はそれをこのように書きます：

use strict;
use warnings;
use Parse::RecDescent;
use Data::Dumper;

my $parser = Parse::RecDescent->new(<<'EOT');
event_function: object_list ':' event_list(?) ';'
    {
        $return = $item[1];
    }

object_list : <leftop: object ',' object>
    {
        $return = { map { %$_ } @{$item[1]} };
    }

object : 
    '/' /[a-z0-9_][a-z0-9_]*/ '/' '...'
        {
            $return = { $item[2] => 'stuff' };
        }
    |  /[a-z0-9_][a-z0-9_]*/
        { 
            $return = { $item[1] => 'stuff' };
        }

# stub, don't know what this should be
event_list : /[^;]+/

EOT

my %object;

while (<DATA>) {
    my $x = $parser->event_function($_);

    next unless $x;

    # merge objects into master list
    while (my ($k, $v) = each %$x) {
        $object{$k} = $v;
    }
}

print Dumper \%object;

__DATA__
stuff, stuff2: pre-operation event = {foo1, foo2};
stuff3, stuff4: ;

出力は次のとおりです。

$VAR1 = {
          'stuff2' => 'stuff',
          'stuff3' => 'stuff',
          'stuff' => 'stuff',
          'stuff4' => 'stuff'
        };
于 2009-06-04T17:26:00.517 に答える
1

おそらくあなたの質問に対する答えではありませんが、ハッシュを介してeach（）ループを開始するとき、each（）が以前にハッシュで使用されていた場合、イテレータが指している場所から開始します。安全のために、whileループの前にvoid-context keys（）（たとえば、keys（％$ ref1）;）を配置して、イテレータをリセットします。古いバージョンのData::Dumperには、イテレータが最後の要素の直後を指すようにして、安全でないwhile（... each ...）ループに対してハッシュが空のように見えるというかわいいバグがありました:)

于 2009-06-04T17:26:53.900 に答える