1

ここのプロジェクトで奇妙な問題が発生しています。NetConnectionをNetGroupと組み合わせて使用​​してWindowsXP上の2つのローカルAIRアプリケーション間の通信を開始すると、それらは常にNetGroupに正常に接続し、相互にネイバーとして検出します。ただし、Windows 7では、両方のアプリケーションが正常にNetConnectionに接続し、NetGroupはお互いをネイバーとして検出しません。

この問題を再現するために、2つのAIRアプリケーションを次に示します。

RTMFP1：

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx"
applicationComplete="init()">
<fx:Declarations>
    <!-- Place non-visual elements (e.g., services, value objects) here -->

</fx:Declarations>
<fx:Script>
    <![CDATA[
        private var nc:NetConnection;

        private var group:NetGroup;

        [Bindable]
        private var connected:Boolean = false;


        private function init():void
        {
            connect();
        }

        private function connect():void
        {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, netStatus);
            nc.connect("rtmfp:");
        }

        private function netStatus(event:NetStatusEvent):void
        {
            writeText(event.info.code);

            switch (event.info.code)
            {
                case "NetConnection.Connect.Success":
                    setupGroup();
                    break;

                case "NetGroup.Connect.Success":
                    connected = true;
                    break;

                case "NetGroup.Posting.Notify":
                    receiveMessage(event.info.message)
                    break;
            }
        }

        private function setupGroup():void
        {
            var groupspec:GroupSpecifier = new GroupSpecifier("myGroup/groupOne");
            groupspec.postingEnabled = true;
            groupspec.ipMulticastMemberUpdatesEnabled = true;
            groupspec.addIPMulticastAddress("127.0.0.1:30302");

            group = new NetGroup(nc, groupspec.groupspecWithAuthorizations());
            group.addEventListener(NetStatusEvent.NET_STATUS, netStatus);
        }

        private var i:int = 0;

        private function sendMessage():void
        {
            var message:Object = new Object();
            message.sender = group.convertPeerIDToGroupAddress(nc.nearID);
            message.text = "Here's your message!";
            message.random = i++;
            group.post(message);
        }

        public function receiveMessage(message:Object):void
        {
            writeText(message.text);
        }

        private function writeText(txt:String):void
        {
            txtHistory.text += txt + "\n";
        }


        private function btnSend_clickHandler(event:MouseEvent):void
        {
            sendMessage();
        }
    ]]>
</fx:Script>
<s:layout>
    <s:VerticalLayout/>
</s:layout>
<s:TextArea id="txtHistory"
    width="100%" height="100%"/>
<s:Button id="btnSend"
    enabled="{connected}"
    label="Send message"
    click="btnSend_clickHandler(event)"/>
</s:WindowedApplication>

RTMFP2：

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark"
xmlns:mx="library://ns.adobe.com/flex/mx"
applicationComplete="connect()">
<fx:Declarations>
    <!-- Place non-visual elements (e.g., services, value objects) here -->
</fx:Declarations>
<fx:Script>
    <![CDATA[
        private var nc:NetConnection;

        private var group:NetGroup;

        [Bindable]
        private var connected:Boolean = false;


        private function connect():void
        {
            nc = new NetConnection();
            nc.addEventListener(NetStatusEvent.NET_STATUS, netStatus);
            nc.connect("rtmfp:");

        }

        private function netStatus(event:NetStatusEvent):void
        {
            switch (event.info.code)
            {
                case "NetConnection.Connect.Success":
                    setupGroup();
                    break;

                case "NetGroup.Connect.Success":
                    connected = true;
                    break;

                case "NetGroup.Posting.Notify":
                    receiveMessage(event.info.message)
                    break;
            }
        }

        private function setupGroup():void
        {
            var groupspec:GroupSpecifier = new GroupSpecifier("myGroup/groupOne");
            groupspec.postingEnabled = true;
            groupspec.ipMulticastMemberUpdatesEnabled = true;
            groupspec.addIPMulticastAddress("127.0.0.1:30302");

            group = new NetGroup(nc, groupspec.groupspecWithAuthorizations());
            group.addEventListener(NetStatusEvent.NET_STATUS, netStatus);
        }

        private var i:int = 0;

        private function sendAcknowledge():void
        {
            var message:Object = new Object();
            message.text = "We received your message!";
            message.sender = group.convertPeerIDToGroupAddress(nc.nearID);
            message.sequence = i++;
            group.post(message);
        }

        public function receiveMessage(message:Object):void
        {
            writeText(message.text);
            sendAcknowledge();
        }

        private function writeText(txt:String):void
        {
            textArea.text += txt + "\n";
        }
    ]]>
</fx:Script>
<s:layout>
    <s:VerticalLayout/>
</s:layout>
<s:TextArea id="textArea" width="100%" height="100%"/>
</s:WindowedApplication>

これらのアプリケーションは、Windows XPで問題なく相互に接続し、メッセージを送信できます。ただし、Windows7ではできません。

これがWindows7で機能しない理由と、それを機能させるために実行できる手順を知っている人はいますか？これが機能することは、私たちのプロジェクトにとって重要です。

追伸：アプリケーションがネイバーとしてお互いを検出するのに非常に長い時間（場合によっては最大15秒）かかる場合もあれば、すぐにお互いを検出する場合もあります。誰かがこの遅延を引き起こす可能性があるものを知っていますか？

4

1 に答える 1

0

私の最初の推測は、ファイアウォールまたはネットワークのいずれかと関係があると思います。RTMFP は非標準の UDP ポート 1935を使用し、多くのエンタープライズ ファイアウォールはポート 80 または 443 (HTTP、HTTPS) 以外のすべてをブロックします。

これが、p2p が機能しない場合にサード パーティのサーバー フォールバックを使用することをお勧めする理由です。

于 2012-03-01T18:47:47.603 に答える