0

私はディレクトリ構造を持っています:

pakages
|-files.bat
|-component
  |-source
  |-lib

files.bat スクリプトを使用してテキスト ファイルを作成し、次のようなファイル リストを作成する必要があります。

 File0001=source\WindowT.pas
 File0002=source\AWindowT.pas
 File0003=source\AWindowSplash.pas
 File0004=source\InternalT.pas
 File0005=source\ImageLister.pas
 File0006=lib\LIcons.res
 File0007=lib\TstandartBtn_16.RES
 File0008=lib\TstandartBtn_24.RES

......等

そのようなファイルリストを作成する方法は?

前もって感謝します

4

3 に答える 3

2

次のスクリプトをまとめました。

@echo off
setlocal
rem The number of the current file, gets incremented
set FileNumber=1
rem Move into "component" directory, the following "for" command will 
pushd %~dp0\component
rem loop over directories there
for /d %%f in (*) do call :process "%%f"
rem move into the previous directory again
popd
endlocal
goto :eof

:process
rem process files
for /f %%x in ('dir /b /a:-d %1 2^>nul') do call :process_files %~1 %%x
rem go down recursively, if there are more subdirectories
for /f %%d in ('dir /b /a:+d %1 2^>nul') do call :process %%d
goto :eof

:process_files
call :leadingzeros %FileNumber%
rem Output line
echo File%RESULT%=%~1\%2
set /a FileNumber+=1
goto :eof

rem Parameter: a non-negative number <= 9999
rem Result: a string with zero padding at the start
:leadingzeros
if %1 LSS 10 set RESULT=000%1&goto :eof
if %1 LSS 100 set RESULT=00%1&goto :eof
if %1 LSS 1000 set RESULT=0%1&goto :eof
set RESULT=%1
goto :eof

必要なものではないかもしれませんが、出発点を提供する必要があります。ただし、出力は同じです。次のファイル/ディレクトリ ツリーの場合:

    パッケージ
    │files.cmd
    │
    └───コンポーネント
        ├───lib
        │ LIcons.res
        │TstandardBtn_16.RES
        │TstandardBtn_24.RES
        │
        └───出典
                AWindowSplash.pas
                AWindowT.pas
                ImageLister.pas
                内部T.pas
                WindowT.pas

バッチを実行すると、次の出力が生成されます。

File0001=lib\LIcons.res
File0002=lib\TstandardBtn_16.RES
File0003=lib\TstandardBtn_24.RES
File0004=source\AWindowSplash.pas
File0005=source\AWindowT.pas
File0006=source\ImageLister.pas
File0007=source\InternalT.pas
File0008=source\WindowT.pas
于 2009-06-08T13:05:56.790 に答える
0

次のようなものから始めます。

@echo off

call :dodir .
goto eof

:dodir
set TEMP_CUR_DIR="%*"
REM echo Directory %TEMP_CUR_DIR%:
for %%f in (%TEMP_CUR_DIR%\*) do call :dofile %%f
for /d %%d in (%TEMP_CUR_DIR%\*) do call :dodir %%d
goto eof

:dofile
set TEMP_CUR_FILE="%*"
echo File: %TEMP_CUR_FILE%
goto eof

:eof
于 2009-06-08T12:10:30.413 に答える
0 
dir /A:-D /B /S>out.txt

それはあなたが望むもののほとんどを手に入れます.

于 2009-06-08T11:11:24.883 に答える