4

だから私は、通常は命令型言語で行う方法を知っている xslt の問題を解決しようとしています。xml要素のリスト、標準的なものからテーブルにセルを追加しています。そう：

<some-elements>
  <element>"the"</element>
  <element>"minds"</element>
  <element>"of"</element>
  <element>"Douglas"</element>
  <element>"Hofstadter"</element>
  <element>"and"</element>
  <element>"Luciano"</element>
  <element>"Berio"</element>
</some-elements>

ただし、特定の最大文字数に達したら、1 行を切り捨てて新しい行を開始したいと考えています。したがって、1行あたり最大20文字を許可するとします。私はこれで終わるだろう：

<table>
 <tr>
  <td>"the"</td>
  <td>"minds"</td>
  <td>"of"</td>
  <td>"Douglas"</td>
 </tr>
 <tr>
  <td>"Hofstadter"</td>
  <td>"and"</td>
  <td>"Luciano"</td>   
 </tr>
 <tr>
  <td>"Berio"</td>
 </tr>
</table>

命令型言語では、各要素 string-count を可変変数に追加しながら、要素を行に追加します。その変数が 20 を超えると、停止して新しい行を作成し、string-count をゼロに戻した後、その行で (停止した要素から開始して) プロセス全体を再実行します。ただし、XSLT で変数の値を変更することはできません。このステートレスな関数評価全体が、私をループに陥れています。

4

1 に答える 1

9

xsl-list からこのフォーラムに来るのは 10 年前に戻るようなものです。

<xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes"/>

<xsl:template match="some-elements">
 <table>
  <xsl:apply-templates select="element[1]"/>
 </table>
</xsl:template>


<xsl:template match="element">
 <xsl:param name="row"/>
 <xsl:choose>
  <xsl:when test="(string-length($row)+string-length(.))>20
          or
          not(following-sibling::element[1])">
   <tr>
    <xsl:copy-of select="$row"/>
    <xsl:copy-of select="."/>
   </tr>
   <xsl:apply-templates select="following-sibling::element[1]"/>
  </xsl:when>
  <xsl:otherwise>
   <xsl:apply-templates select="following-sibling::element[1]">
    <xsl:with-param name="row">
     <xsl:copy-of select="$row"/>
     <xsl:copy-of select="."/>
    </xsl:with-param>
   </xsl:apply-templates>
  </xsl:otherwise>
 </xsl:choose>
</xsl:template>
</xsl:stylesheet>
于 2012-03-11T10:45:58.083 に答える