2

PDV内のすべての既存の変数を欠落に設定するコマンドまたは簡単な方法はありますか？

私はこのように実行されるいくつかのコードを持っています：

Data example2; 
var1='A';
Var2='B';
Var3='C';
/* etc*/
output;
Var1='B';
output;
stop;
run;

最初の「output」ステートメントに到達したら、すべてのPDV変数を欠落状態にリセットしたいと思います（例：var2 =''; var3 ='';）が、手動でそのように宣言する必要はありません。誰か助けてもらえますか？

4

2 に答える 2

7

呼び出し欠落ルーチンと_all_自動変数リストはそれを簡単に行います

call missing(of _all_);

例えば

Data example2;
var1='A';
Var2='B';
Var3='C';
output;
call missing(of _all_);
Var1='B';
output;
stop;
run;

proc print data=example2;
run;

を生成します

                                 The SAS System

                               Obs    var1    Var2    Var3

                                1      A       B       C
                                2      B
于 2009-06-10T13:54:22.757 に答える
1

あなたは配列でそれを行うことができます。

これは、PDVのすべてを欠落させるマクロです。パラメータtは、単一のデータステップから複数回呼び出すことができるようにするためのものです。


%macro cleanpdv(t);
array __c&t{*} _character_;
array __n&t{*} _numeric_;
do __i&t=1 to dim(__c&t);
  call missing(__c&t{__i&t});
end;
do __i&t=1 to dim(__n&t);
  call missing(__n&t{__i&t});
end;
drop __i&t;
%mend;

あなたはそれをこのように使うかもしれません：



Data example2;
var1='A';
Var2='B';
Var3='C';
/* etc*/
output;
%cleanpdv(1);
Var1='B';
output;
%cleanpdv(2);
output;
stop;
run;

これにより、次のデータセットが生成されます。

  Obs var1 Var2 Var3

   1 ABC
   2 B
   3
于 2009-06-10T07:22:59.910 に答える