0

つまり、基本的にはJugというMovieClipがあり、卵をクリックしてJugにドラッグすると、それを非表示にして、最初に開始した場所に再度追加します。これに加えて、変数に1の値を追加する必要があります。

しばらくこれをいじってみましたが、子を削除するとエラーが発生するため、わかりません。コードは次のとおりです。

var eggClickOffset:Point = null;
var egg:Egg = new Egg();
egg.x = 290;
egg.y = 330;
addChild(egg);
var eggAmount:TextField = new TextField();
eggAmount.defaultTextFormat = textFormat;
eggAmount.x = 250;
eggAmount.y = 60;
eggAmount.height = 18;
eggAmount.width = 100;
eggAmount.border = true;
eggAmount.text = "Incorrect Amount";
eggAmount.background = true;
eggAmount.backgroundColor = 0xff0000;
stage.focus = eggAmount;
addChild(eggAmount);
var eggs:int;
eggs = 0;

//Egg Event listeners:
egg.addEventListener(Event.ENTER_FRAME, eggAmountCounter);
egg.addEventListener(MouseEvent.MOUSE_DOWN, startEggDrag);
egg.addEventListener(MouseEvent.MOUSE_UP, stopEggDrag);
egg.addEventListener(Event.ENTER_FRAME, dragEgg);
egg.addEventListener(Event.ENTER_FRAME, checkEggCollision);

//starting egg drag:
function startEggDrag(event:MouseEvent):void
{
    eggClickOffset = new Point(event.localX,event.localY);
}

//Stopping the egg drag:
function stopEggDrag(event:MouseEvent):void
{
    eggClickOffset = null;
}

//Egg Dragging:
function dragEgg(event:Event):void
{
    if (eggClickOffset != null)
    {// must be dragging
        egg.x = mouseX - eggClickOffset.x;
        egg.y = mouseY - eggClickOffset.y;
    }
}

//When egg hits jug:
function checkEggCollision(event:Event):void
{
    if (jug.hitTestObject(egg))
    {
            eggs + 1;
            egg.removeEventListener(MouseEvent.MOUSE_DOWN, startEggDrag);
            egg.removeEventListener(Event.ENTER_FRAME, dragEgg);
            removeChild(egg);
            addChild(egg);
            egg.x = 300;
            egg.y = 300;
    }
}

//How many eggs:
function eggAmountCounter(event:Event):void {
    if(eggs == 3){
        eggAmount.text = "Corrent Amount";
    }
}
4

2 に答える 2

2

したがって、コンテナに物を追加したり、コンテナから物を削除したりすることは、ツールキットがそれ自体を再描画するために何をしなければならないかという点で、実際にはかなりの費用がかかります。そして、通常、このような問題が発生し、宣伝どおりに機能しない場合があります。したがって、可視性を制御したい場合は、コンポーネントを追加/削除しないことをお勧めします。それらをvisible=false / trueとマークするだけで、オプションでincludeInLayout = true/falseを使用することを忘れないでください。ムービークリップが表示されているので、true/falseで十分です。

卵を元の位置に戻したいだけの場合は、x、yの位置を直接変更するだけです。卵を取り込んで、すべてのプロパティを初期状態に設定する簡単なメソッドを作成します。stopEggDragメソッドで、画面上でドラッグされていた卵を渡す関数を呼び出すだけです。ビオラそれは元の場所に戻ります。

ここでの秘訣は、オブジェクトを削除しない場合でも、削除の問題を解決する必要がないことです。

于 2012-03-15T18:34:22.007 に答える
1

申し訳ありませんが、removeChildでエラーは発生していませんが、次の理由により、eggを移動できなくなったことを意味します。

egg.removeEventListener(MouseEvent.MOUSE_DOWN, startEggDrag);

ところで、この場合、3xEvent.ENTER_FRAMEは必要ないと確信しています。

別のアプローチを提案してもいいですか？多分あなたはこのような何かを試すことができます：

var eggStartPos:Point;
egg.addEventListener(MouseEvent.MOUSE_DOWN, startEggDrag);
egg.addEventListener(MouseEvent.MOUSE_UP, stopEggDrag);

//starting egg drag:
function startEggDrag(event:MouseEvent):void
{
    eggStartPos = new Point(egg.x, egg.y);
    egg.addEventListener(Event.ENTER_FRAME, handle_enterFrame);
}

//Stopping the egg drag:
function stopEggDrag(event:MouseEvent):void
{
    egg.removeEventListener(Event.ENTER_FRAME, handle_enterFrame);
    eggStartPos = null;
}

//Handle egg moving and hittest on enter frame
function handle_enterFrame(event:Event):void
{
    egg.x = mouseX;
    egg.y = mouseY;

    if( collisionWithJug(egg) )
    {
        egg.removeEventListener(Event.ENTER_FRAME, handle_enterFrame);
        collisionOccur();
    }
}

function collisionWithJug(target:DisplayObject):Boolean
{
    if (jug.hitTestObject(target))
        return true;
    else
        return false;
}

//Got collision
function collisionOccur():void
{
    eggs += 1;
    egg.x = eggStartPos.x;
    egg.y = eggStartPos.y;

    eggAmountCounter();
}


//How many eggs:
function eggAmountCounter():void
{
    if(eggs == 3)
    {
        eggAmount.text = "Corrent Amount";
    }
}
于 2012-03-15T23:53:26.053 に答える