3

現在、Erlang のプッシュ通知モジュールを作成しようとしています。

トークンが有効な場合、すべてが正常に機能します... 問題は、古いデバイス トークン (現在は無効) が拒否された場合です。無効なトークンは、apns によって 6 バイトのソケット メッセージで拒否され、接続が無効になることを理解しています (これは本当にばかげていると思いますが、何でも...)

問題は、制御プロセスがソケットをリッスンしていないように、APNS がモジュールで提供する必要がある 6 バイトのソケット メッセージを取得していないようです。

これが私のコードです:

-module(pushiphone).
-behaviour(gen_server).

-export([start/1, init/1, handle_call/3, handle_cast/2, code_change/3, handle_info/2, terminate/2]).

-import(ssl, [connect/4]).
-record(push, {socket, pid, state, cert, key}).

start(Provisioning) ->
    gen_server:start_link(?MODULE, [Provisioning], []).

init([Provisioning]) ->
    gen_server:cast(self(), {connect, Provisioning}),
    {ok, #push{pid=self()}}.

send(Socket, DT, Payload) ->
    PayloadLen = length(Payload),
    DTLen = size(DT),
    PayloadBin = list_to_binary(Payload),
    Packet = <<0:8, 
           DTLen:16/big, 
           DT/binary, 
           PayloadLen:16/big, 
           PayloadBin/binary>>,
    ssl:send(Socket, Packet).

handle_call(_, _, P) ->
    {noreply, P}.

handle_cast({connect, Provisioning}, P) ->
    case Provisioning of
    dev -> Address = "gateway.sandbox.push.apple.com";
    prod -> Address = "gateway.push.apple.com"
    end,
    Port = 2195,
    Cert="/apns-" ++ atom_to_list(Provisioning) ++ "-cert.pem",
    Key="/apns-" ++ atom_to_list(Provisioning) ++ "-key.pem",
    Options = [{certfile, Cert}, {keyfile, Key}, {password, "********"}, {mode, binary}, {active, false}],
    Timeout = 1000,
    {ok, Socket} = ssl:connect(Address, Port, Options, Timeout),
    ssl:controlling_process(Socket, self()), %% Necessary ??
    gproc:reg({n,l, pushiphone}),
    {noreply, P#push{socket=Socket}};
handle_cast(_, P) ->
    {noreply, P}.

handle_info({ssl, Socket, Data}, P) ->
    <<Command, Status, SomeID:32/big>> = Data,
    io:fwrite("[PUSH][ERROR]: ~p / ~p / ~p~n", [Command, Status, SomeID]),
    ssl:close(Socket),
    {noreply, P};
handle_info({push, message, DT, Badge, [Message]}, P) ->
    Payload = "{\"aps\":{\"alert\":\"" ++ Message ++ "\",\"badge\":" ++ Badge ++ ",\"sound\":\"" ++ "msg.caf" ++ "\"}}",
    send(P#push.socket, DT, Payload),
    {noreply, P};
handle_info({ssl_closed, _SslSocket}, P) ->
    io:fwrite("SSL CLOSED !!!!!!~n"),
    {stop, normal, P};
handle_info(AnythingElse, P) ->
    io:fwrite("[ERROR][PUSH][ANYTHING ELSE] : ~p~n", [AnythingElse]),
    {noreply, P}.

code_change(_, P, _) ->
    {ok, P}.

terminate(_, _) ->
    ok.

したがって、モジュールを開始して有効なトークンにプッシュすると、電話でプッシュが受信されますが、無効なトークンにプッシュしてから有効なトークンにプッシュすると、有効なトークンはプッシュを受け取りません.. .

データベースからデバイス トークンを削除するには、フィードバック サービスをリッスンする必要があることは承知していますが、再接続するには、プッシュ ゲートウェイが接続を無効にしたかどうかも確認する必要があります。

本当の質問は次のとおりです。なぜ私の gen-server はエラー応答パケットを受信しないのですか (これは handle_info({ssl, Socket, Data}, P) と一致するはずです)。

4

1 に答える 1

4

ソケットは active=false で構成されています。active=true (または繰り返し active=once) に設定しない限り、メッセージは受信されません。inet:setopts/2のドキュメントを参照してください。

また、controller_process を self() に設定する必要もありません。

于 2012-03-21T21:21:48.807 に答える