1

名前空間URIの一部を別の文字列に置き換えようとしている入力SOAPメッセージがあります。URI全体を別のURIに置き換えることはできますが、既存のURIを変更することはできません。「OLDSTRING」を探して「NEWSTRING」に置き換える必要があります。文字列VARIABLESTRINGは、入力xmlごとに異なるため、出力xmlにそのまま保持する必要があります。

入力XML：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:urn="urn:schemas-OLDSTRING-com:VARIABLESTRING">
       <soapenv:Header/>
       <soapenv:Body>
          <requestMessage xmlns="urn:schemas-OLDSTRING-com:VARIABLESTRING">
            <merchantID>TESTID</merchantID>   
          </requestMessage>
       </soapenv:Body>
    </soapenv:Envelope>

出力XML：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:urn="urn:schemas-NEWSTRING-com:transaction-data-1.69">
   <soapenv:Header/>
   <soapenv:Body>
      <requestMessage xmlns="urn:schemas-NEWSTRING-com:VARIABLESTRING">
        <merchantID>TESTID</merchantID>   
      </requestMessage>
   </soapenv:Body>
</soapenv:Envelope>

次のXSLを試し、名前空間URIを変更できましたが、「OLDSTRING」のみを「NEWSTRING」に置き換え、残りの文字列をそのままにしておきたいと思います。

XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
       <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="@*|*|text()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="//*[namespace-uri()='urn:schemas-OLDSTRING-com:VARIABLESTRING']">
        <xsl:element name="{local-name()}" namespace="urn:schemas-NEWSTRING-com:VARIABLESTRING" >
            <xsl:apply-templates select="@*|*|text()" />
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>
4

2 に答える 2

0

これはあなたが望むことをしますか？

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="@*|*|text()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="//*[namespace-uri()='urn:schemas-OLDSTRING-com:VARIABLESTRING']">
        <xsl:element name="{local-name()}" namespace="{replace(namespace-uri(), 'OLDSTRING', 'NEWSTRING')}" >
            <xsl:apply-templates select="@*|*|text()" />
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>
于 2012-03-30T00:47:20.093 に答える
0

この種の処理はXSLT2.0では簡単ですが、XSLT1.0ではかなり注意が必要です。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pTarget" select="'OLDSTRING'"/>
 <xsl:param name="pRepl" select="'NEWSTRING'"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match=
  "*[starts-with(namespace-uri(), 'urn:schemas')
   or
     namespace::*[starts-with(., 'urn:schemas')]
    ]">

  <xsl:variable name="vNS" select="namespace-uri()"/>

  <xsl:variable name="vNewNS">
    <xsl:choose>
      <xsl:when test="not(contains($vNS, $pTarget))">
        <xsl:value-of select="$vNS"/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="substring-before($vNS, $pTarget)"/>
        <xsl:value-of select="$pRepl"/>
        <xsl:value-of select="substring-after($vNS, $pTarget)"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:variable>

  <xsl:element name="{name()}" namespace="{$vNewNS}">
   <xsl:copy-of select=
     "namespace::*
        [not(. = $vNS
            or
             starts-with(., 'urn:schemas')
           and
             contains(., $pTarget)
             )
        ]"/>

   <xsl:for-each select=
     "namespace::*
        [starts-with(., 'urn:schemas')
       and
         contains(., $pTarget)
        ]">
     <xsl:variable name="vNewNSUri" select=
     "concat(substring-before(., $pTarget),
             $pRepl,
             substring-after(., $pTarget)
             )
     "/>

     <xsl:variable name="vPrefix" select="name()"/>

     <xsl:variable name="vPref">
       <xsl:if test="$vPrefix">
         <xsl:value-of select="concat($vPrefix, ':')"/>
       </xsl:if>
     </xsl:variable>

     <xsl:variable name="vrtfDoc">
      <xsl:element name="{$vPref}dummy"
                   namespace="{$vNewNSUri}"/>
     </xsl:variable>

     <xsl:copy-of select=
     "ext:node-set($vrtfDoc)/*/namespace::*[. = $vNewNSUri]"/>
   </xsl:for-each>

   <xsl:apply-templates select="node()|@*"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

この変換が提供されたXMLドキュメントに適用される場合：

<soapenv:Envelope
xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:urn="urn:schemas-OLDSTRING-com:VARIABLESTRING">
    <soapenv:Header/>
    <soapenv:Body>
        <requestMessage xmlns="urn:schemas-OLDSTRING-com:VARIABLESTRING">
            <merchantID>TESTID</merchantID>
        </requestMessage>
    </soapenv:Body>
</soapenv:Envelope>

必要な正しい結果が生成されます：

<soapenv:Envelope
xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:urn="urn:schemas-NEWSTRING-com:VARIABLESTRING">
  <soapenv:Header />
  <soapenv:Body>
    <requestMessage xmlns="urn:schemas-NEWSTRING-com:VARIABLESTRING">
      <merchantID>TESTID</merchantID>
    </requestMessage>
  </soapenv:Body>
</soapenv:Envelope>
于 2012-03-30T04:45:01.473 に答える