5

リモートの MySQL ベースを操作する簡単な例を見つけたいと思います。ADODB.Connectionと接続文字列の設定方法を説明するチュートリアルがインターネット上にいくつかあることは知っていますが、うまくいきませんでした。助けてくれてありがとう！

4

1 に答える 1

7

MySQL ダウンロード ページから をダウンロードしODBC connectorます。

ここconnectionstringで右を探してください。

VB6 プロジェクトで、への参照を選択しますMicrosoft ActiveX Data Objects 2.8 Library。Windows Vista または Windows 7 を使用している場合は、6.0 ライブラリもある可能性があります。プログラムを Windows XP クライアントでも実行したい場合は、2.8 ライブラリを使用するよりも優れています。SP 1 を適用した Windows 7 を使用している場合、SP1 の互換性バグにより、プログラムはスペックの低い他のシステムでは実行されません。このバグの詳細については、KB2517589を参照してください。

このコードは、ODBC コネクタを使い始めるのに十分な情報を提供します。

Private Sub RunQuery()
    Dim DBCon As adodb.connection
    Dim Cmd As adodb.Command
    Dim Rs As adodb.recordset
    Dim strName As String

    'Create a connection to the database
    Set DBCon = New adodb.connection
    DBCon.CursorLocation = adUseClient
    'This is a connectionstring to a local MySQL server
    DBCon.Open "Driver={MySQL ODBC 5.1 Driver};Server=localhost;Database=myDataBase; User=myUsername;Password=myPassword;Option=3;"

    'Create a new command that will execute the query
    Set Cmd = New adodb.Command
    Cmd.ActiveConnection = DBCon
    Cmd.CommandType = adCmdText
    'This is your actual MySQL query
    Cmd.CommandText = "SELECT Name from Customer WHERE ID = 1"

    'Executes the query-command and puts the result into Rs (recordset)
    Set Rs = Cmd.Execute

    'Loop through the results of your recordset until there are no more records
    Do While Not Rs.eof
        'Put the value of field 'Name' into string variable 'Name'
        strName = Rs("Name")

        'Move to the next record in your resultset
        Rs.MoveNext
    Loop

    'Close your database connection
    DBCon.Close

    'Delete all references
    Set Rs = Nothing
    Set Cmd = Nothing
    Set DBCon = Nothing
End Sub
于 2012-04-05T08:09:04.283 に答える