sql - ストアドプロシージャから複数の行を返す方法は？（Oracle PL / SQL）

Question

引数に応じて異なるレコードのセットを返す1つの引数を持つストアドプロシージャを作成したいと思います。これを行う方法は何ですか？プレーンSQLから呼び出すことはできますか？

Answer 1

テーブルであるかのようにクエリできる結果セットを返す関数を作成する方法を次に示します。

SQL> create type emp_obj is object (empno number, ename varchar2(10));
  2  /

Type created.

SQL> create type emp_tab is table of emp_obj;
  2  /

Type created.

SQL> create or replace function all_emps return emp_tab
  2  is
  3     l_emp_tab emp_tab := emp_tab();
  4     n integer := 0;
  5  begin
  6     for r in (select empno, ename from emp)
  7     loop
  8        l_emp_tab.extend;
  9        n := n + 1;
 10       l_emp_tab(n) := emp_obj(r.empno, r.ename);
 11     end loop;
 12     return l_emp_tab;
 13  end;
 14  /

Function created.

SQL> select * from table (all_emps);

     EMPNO ENAME
---------- ----------
      7369 SMITH
      7499 ALLEN
      7521 WARD
      7566 JONES
      7654 MARTIN
      7698 BLAKE
      7782 CLARK
      7788 SCOTT
      7839 KING
      7844 TURNER
      7902 FORD
      7934 MILLER

Answer 2

私はあなたがREFCURSORを返したいと思います：

create function test_cursor 
            return sys_refcursor
            is
                    c_result sys_refcursor;
            begin
                    open c_result for
                    select * from dual;
                    return c_result;
            end;

更新：SQLからこれを呼び出す必要がある場合は、@TonyAndrewsが提案したようなテーブル関数を使用してください。

Answer 3

Oracleパイプライン関数を使用できます

基本的に、PLSQL（またはjavaまたはc）ルーチンをテーブルではなくデータの「ソース」にしたい場合は、パイプライン関数を使用します。

簡単な例-いくつかの乱数の生成
入力引数に応じて、N個の一意の乱数をどのように作成できますか？

create type array
as table of number;


create function  gen_numbers(n in number default null)
return array
PIPELINED
as
begin
  for i in 1 .. nvl(n,999999999)
  loop
     pipe row(i);
 end loop;
 return;
end;

何かのために3つの行が必要だったとしましょう。これは、次の2つの方法のいずれかで実行できます。

select * from TABLE(gen_numbers(3));

COLUMN_VALUE

---

       1
       2
       3

また

select * from TABLE(gen_numbers)
 where rownum <= 3;

COLUMN_VALUE

---

       1
       2
       3

pipelied Functions1 pipelied Functions2

Answer 4

プレーンSQLで使用したい場合は、ストアプロシージャに結果の行をテーブルまたは一時テーブルに入力させます（または@Tony Andrewsアプローチを使用します）。
@Thilo のソリューションを使用する場合は、PL/SQL を使用してカーソルをループする必要があります。ここに例があります:(@Thiloのように、関数の代わりにプロシージャを使用しました)

create or replace procedure myprocedure(retval in out sys_refcursor) is
begin
  open retval for
    select TABLE_NAME from user_tables;
end myprocedure;

 declare 
   myrefcur sys_refcursor;
   tablename user_tables.TABLE_NAME%type;
 begin
   myprocedure(myrefcur);
   loop
     fetch myrefcur into tablename;
     exit when myrefcur%notfound;
     dbms_output.put_line(tablename);
   end loop;
   close myrefcur;
 end;

Answer 5

create procedure <procedure_name>(p_cur out sys_refcursor) as begin open p_cur for select * from <table_name> end;