xslt - XSL との最初の遭遇時にのみ XML 属性値を表示する

Answer 1

XMLで最初に見つかったsvrl：failed-assert要素の「結果の観察-警告検証フェーズ」メッセージの段落のみを出力したいようですが、他の要素は出力しません。

あなたがする必要があるのは、最初の段落を出力できる最初のそのような要素に一致するテンプレートを用意し、次に他のすべての要素にも一致する名前付きテンプレートsvrl：failed-assertを呼び出すことです。

<xsl:template match="svrl:failed-assert[1]">
   <p>
      <u>
         <xsl:value-of select="(preceding-sibling::svrl:active-pattern)/@name[1]"/>
      </u>
   </p>
   <xsl:call-template name="svrl:failed-assert"/>
</xsl:template>

<xsl:template match="svrl:failed-assert" name="svrl:failed-assert">
    <!-- Existing code here -->

これが簡略化されたXSLTです（検索と置換のコードはありません）

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:svrl="oh:no" exclude-result-prefixes="svrl">
   <xsl:output method="html" indent="yes"/>
   <xsl:template match="svrl:failed-assert[1]">
      <p>
         <u>
            <xsl:value-of select="(preceding-sibling::svrl:active-pattern)/@name[1]"/>
         </u>
      </p>
      <xsl:call-template name="svrl:failed-assert"/>
   </xsl:template>
   <xsl:template match="svrl:failed-assert" name="svrl:failed-assert">
      <table width="800">
         <tr>
            <td colspan="2">
               <font color="red">
                  <xsl:value-of select="svrl:text"/>
               </font>
            </td>
         </tr>
         <tr>
            <td width="50">Test:</td>
            <td width="750">
               <i>
                  <xsl:value-of select="@test"/>
               </i>
            </td>
         </tr>
      </table>
   </xsl:template>
</xsl:stylesheet>

次の簡略化されたXMLに適用した場合：

<a xmlns:svrl="oh:no">
   <svrl:active-pattern name="Result observation - warning validation phase"/>
   <svrl:fired-rule context="Context 1"/>
   <svrl:failed-assert test="Test 1" location="Location 1">
      <svrl:text>Text 1</svrl:text>
   </svrl:failed-assert>
   <svrl:failed-assert test="Test 2" location="Location 2">
      <svrl:text>Text 2</svrl:text>
   </svrl:failed-assert>
   <svrl:fired-rule context="Context 2"/>
   <svrl:failed-assert test="Test 3" location="Location 3">
      <svrl:text>Text 3</svrl:text>
   </svrl:failed-assert>
</a>

次のHTMLが出力されます。

<p>
   <u>Result observation - warning validation phase</u>
</p>
<table width="800">
   <tr>
      <td colspan="2">
         <font color="red">Text 1</font>
      </td>
   </tr>
   <tr>
      <td width="50">Test:</td>
      <td width="750">
         <i>Test 1</i>
      </td>
   </tr>
</table>
<table width="800">
   <tr>
      <td colspan="2">
         <font color="red">Text 2</font>
      </td>
   </tr>
   <tr>
      <td width="50">Test:</td>
      <td width="750">
         <i>Test 2</i>
      </td>
   </tr>
</table>
<table width="800">
   <tr>
      <td colspan="2">
         <font color="red">Text 3</font>
      </td>
   </tr>
   <tr>
      <td width="50">Test:</td>
      <td width="750">
         <i>Test 3</i>
      </td>
   </tr>
</table>