1

私はこのようなcsvファイルを持っています

name,sex,age
venu,m,16
test,,22

[編集]
名前にはカンマも含めることができます

"venu,gopal",m,16

性別が無かったら処理して別のファイルに保存したいです。

私はこのようなスクリプトを持っています

@Echo Off
For /F "usebackq tokens=1-3  delims=," %%a in (test.csv) Do (
   echo %%a, %%b, %%c >> test-new.csv
)

しかし、3番目のレコードでは、%%bを22として取得しています。これはスペースである必要があります。これを修正する方法は？

[編集2]

私はそのリンクに従って試しました。何が間違っているのかわかりません。同じ問題が発生しています。一度確認してください。

@echo off
setlocal DisableDelayedExpansion

For /F "usebackq tokens=1-3 delims=" %%x in (C:\somefile.csv) Do (

    setlocal EnableDelayedExpansion
    set "var=%%x"   

    set "var=!var:"=""!"
    set "var=!var:^=^^!"
    set "var=!var:&=^&!"
    set "var=!var:|=^|!"
    set "var=!var:<=^<!"
    set "var=!var:>=^>!"
    set "var=!var:,=^,^,!"
    set var=!var:""="!
    set "var=!var:"=""Q!"
    set "var=!var:,,="S"S!"
    set "var=!var:^,^,=,!"
    set "var=!var:""="!"
    set "var=!var:"Q=!"


    For /F "tokens=1-3  delims=," %%a in ("!var:"S"S=","!") Do (
      endlocal
      echo %%~a, %%~b, %%~c
      setlocal EnableDelayedExpansion
      pause
    )

    endlocal

)
4

2 に答える 2

2

複数のデリムが単一のデリムに凝縮されるため、これは少し注意が必要です。

したがって、前にそれらを一意のデリムシーケンスに置き換える必要があります。

@Echo Off
setlocal DisableDelayedExpansion
For /F "usebackq tokens=1-3  delims=" %%a in (test.csv) Do (
    set "line=%%a"
    setlocal EnableDelayedExpansion
    set "line="!line:,=","!""
    For /F "tokens=1-3  delims=," %%a in ("!line!") Do (
        echo %%~a, %%~b, %%~c 
    )
)

これにより、各列が引用符で囲まれ%%~a、引用符は後で削除されます

編集：埋め込まれたコンマの解決策

この場合、';'で分割する方法のソリューションとは少し異なります。CMDシェルで

@echo off
setlocal DisableDelayedExpansion

For /F "usebackq tokens=1-3 delims=" %%x in (test.csv) Do (
    set "var=%%x"
    setlocal EnableDelayedExpansion
    set "var=!var:^=^^!"
    set "var=!var:&=^&!"
    set "var=!var:|=^|!"
    set "var=!var:<=^<!"
    set "var=!var:>=^>!"
    set "var=!var:,=^,^,!"
    rem ** This is the key line, the missing quote is intention
    call set var=%%var:""="%%
    set "var=!var:"="Q!"
    set "var=!var:^,^,="C!"
    set "var=!var:,,=,!"
    set "var=!var:""="!"

    set "var="!var:,=","!""
    for /F "tokens=1-3 delims=," %%a in ("!var!") do (      
        endlocal
        set "col1=%%~a"
        set "col2=%%~b"
        set "col3=%%~c"
        setlocal EnableDelayedExpansion
        if defined col1 (
            set "col1=!col1:"C=,!"
            set "col1=!col1:"Q="!"
        )

        if defined col2 (
            set "col2=!col2:"C=,!"
            set "col2=!col2:"Q="!"
        )

        if defined col3 (
            set "col3=!col3:"C=,!"
            set "col3=!col3:"Q="!"
        )
        echo a=!col1!, b=!col2!, c=!col3!
        endlocal
    )
)
于 2012-05-21T13:29:18.830 に答える
0

SSEDのような文字列エディタを使用して、「,,」を「、-」に2回置き換えた一時ファイルを作成し、「-」を元のファイルの空のフィールドと見なすことで、この問題を解決しました。 ..

 ssed "s/,,/,-,/ig;s/,,/,-,/ig" file1.csv > file1.tmp

その後、トークンは正しく割り当てられます。一時ファイルを編集してからCSVに戻る必要がある場合は、...を使用します。

 ssed "s/,-,/,,/ig;s/,-,/,,/ig" file1.tmp > file1.csv

これは、飛行中の文字列をトークンで置き換えたり、サブルーチンなどを使用したりするよりもはるかに簡単なようです。

于 2013-07-08T17:00:42.837 に答える