5

私は Schaum の Outline of Programming With Fortran 77 本を使用しています。値のグループをブラケットする方法を使用したバイナリ検索の例があります。まず、コードは次のとおりです。

    INTEGER X(100)
    INTEGER RANGE
    INTEGER START , FINISH

    PRINT *, 'Number of values ?'
    READ *, N
    DO 10 I = 1, N
        READ *, X(I)
    END DO 

    PRINT *, 'Enter Value'
    READ *, VAL

    START =  1 
    FINISH = N
    RANGE = FINISH - START 
    MID = (START + FINISH) /2

    DO WHILE( X(MID) .NE. VAL .AND. RANGE .NE. 0)
      IF (VAL .GT. X(MID))THEN
        START = MID 
      ELSE 
        FINISH = MID
      END IF
      RANGE = FINISH - START
      MID = (START + FINISH)/2
    END DO 

    IF( X(MID) .NE. VAL) THEN
      PRINT *, VAL, 'NOT FOUND'
    ELSE
      PRINT *, 'VALUE AT' , MID
    END IF
    END

問題は、次のような7つの値の配列を入力すると

2 | 9 | 11 | 23 | 49 | 55 | 66

たとえば、次の場合に 66 を検索します。

ミッド = 5

、次のループの新しい MID は 6 になります。しかし、それが 6 のときは、次のループのためにインクリメントできません。

ミッド = (スタート + フィニッシュ)/2 = (6+7)/2 = 6

もちろん、7になるはずです。

それはまだ6です。もちろん、私のプログラムは決して出力を与えません。ここで何をしようか？

4

1 に答える 1

11

これは単なるタイプミスであるか、Cバージョンから翻訳したときに混乱し、インデックスを変更しなければならなかった可能性があります。

ループ内の重要な不変条件は、値がリストにある場合、インデックスの開始から終了までのどこかに配列内に含まれている必要があることです。ただし、midを除外したら、リストから削除する必要があります。しかし、ここにはないので、リストは常に長すぎて、発生した問題に遭遇します。

正しいバージョンでは、開始をmid + 1に設定するか、終了をmid-1に設定して、midを除外します。Fortran 90スタイルで記述された修正されたコード：

program binarysearch

    implicit none
    integer, allocatable, dimension(:) ::  x
    integer :: range, start, finish, mid
    integer :: i, n, val

    print *, 'Number of values ?'
    read *, N
    allocate( x(N) )

    do i = 1, n
        READ *, x(i)
    end do

    print *, 'Enter Value'
    read *, VAL

    start =  1
    finish = N
    range = finish - start
    mid = (start + finish) /2

    do while( x(mid) /= val .and. range >  0)
      if (val > x(mid)) then
        start = mid + 1
      else
        finish = mid - 1
      end if
      range = finish - start
      mid = (start + finish)/2
    end do

    if( x(mid) /= val) then
      print *, val, 'NOT FOUND'
    else
      print *, 'VALUE AT' , mid
    end if

    deallocate( x )

end program binarysearch
于 2012-06-15T00:33:55.200 に答える