perl - プログラムが実行されているかどうかを確認し、perl で実行されていない場合は実行します

Question

プログラムが実行されているかどうかを確認し、そうでない場合はこのプログラムを実行する方法を知りたいです。

Answer 1

kill 関数を使用して、確認したいプロセス ID に 0 (ゼロ) シグナルを送信します。プロセスが存在する場合、関数は true を返し、そうでない場合は false を返します。

例：

#-- check if process 1525 is running
$exists = kill 0, 1525;
print "Process is running\n" if ( $exists );

システムコールを使用してコマンドラインから行うのと同じように、任意のプログラムを呼び出すことができます。これは、プログラムの出力をキャプチャする必要がない場合にのみ役立ちます。

#!/usr/bin/perl
use strict;
use warnings;
my $status = system("vi fred.txt");

または、シェルを関与させたくない場合:

#!/usr/bin/perl
use strict;
use warnings;
my $status = system("vi", "fred.txt");

Answer 2

別の回答と同様ですが、「grep -v grep」を使用して、grep 呼び出し自体と一致しないようにする必要があります。これにより、必要のないときに true に評価されないようになります。

use strict;
use warnings;

my($cmd, $process_name) = ("command here", "process name here");

if(`ps -aef | grep -v grep $process_name`) {
    print "Process is running!\n";
}#if
else {
    `$cmd &`;
}#else

Answer 3

これを使用して、Linux のデーモン起動 pid ファイルの内容に基づいて、デーモンが実行されているかどうかを確認します。

#!/usr/local/bin/perl
use strict;
use warnings;

use feature qw/ say /;

# vars we report
my (
    $token,         # optional arg - check against cmd_line if specified
    $pid_file,      # daemon pid-file, e.g. /var/run/mysqld/mysqld.pid
    $pid,           # the pid to investigate...
    $pid_running,   # found a pid and it is running
    $cmd_line,      # cmd_line of the running pid
    $result,        # 0-OK, 1=FAIL, exit value
    $error,         # error message if necessary
  );

# working vars
my ( $fh, $cmd_file );

die "Daemon pid-file required" unless scalar @ARGV >= 1;
( $pid_file, $token ) = @ARGV;

if ( -s $pid_file ) {
  open( $fh, "<", $pid_file ) or die "open $pid_file: $!";
  ( $pid ) = <$fh>; chomp $pid; close $fh;

  $pid_running = kill 0, $pid;

  if ( $pid_running ) {
    $cmd_file = "/proc/$pid/cmdline";
    local($/) = "\0"; # C-String NULL terminated
    open( $fh, "<", $cmd_file ) or die "open $cmd_file: $!";
    ( $cmd_line ) = <$fh>; close $fh;
    if ( $cmd_line && $token && $cmd_line !~ m/$token/ ) {
      $error = "token not found: $token in $cmd_line";
    }
  }
  else {
    $error = "process not found: $pid";
  }
}
else {
  $error = "file not found: $pid_file";
}

# if TOKEN - OK running process with matching cmdline
$result = $token ? ( $pid_running && $cmd_line && $cmd_line =~ m/$token/ )
                 : ( $pid_running || 0 );

say "token:     ", $token if $token;
say "file:      ", $pid_file;
if ( $pid ) {
  say "pid:       ", $pid;
  say "running:   ", $pid_running;
  say "cmdline:   ", $cmd_line if $cmd_line;
}
say "error:     ", $error if $error;
say "exit:      ", $result ? 'ok' : 'fail';

exit $result;