3

画面に何かを描画して、それをステージ上のビットマップにコピーしようとしています。

以前、円のような手続き的に描画された形状でこれを行ったことがありますが、ライブラリ アイテムを使用すると、ほとんどのソース ピクセルが切り取られます。

これが私のコードです - 別の関数では、ビットマップ オブジェクトがステージに追加され、copyPixels が機能することがわかりますが、先ほど述べたように、一部のピクセルのみがコピーされます。Rectangle で遊んでみましたが、今のところうまくいきません。

var s:StarAsset = new StarAsset();

        s.x = e.stageX;
        s.y = e.stageY;
        s.scaleX = e.pressure * 10;
        s.scaleY = e.pressure * 10;
        s.rotation = Math.random() * 360;



        var bms:BitmapData = new BitmapData(s.width + 6, s.height + 6, true, 0x00000000);
        bms.draw(s);

        var srect:Rectangle = new Rectangle();
        srect.width = s.width + 6;
        srect.height = s.height + 6;

        var destpoint:Point = new Point(s.x, s.y);
        bmcontainer.copyPixels(bms, srect, destpoint, null, null, true);
4

1 に答える 1

6

スター アセットの使用:

スターアセット

そして、ステージ上のキャンバス ビットマップにブリットしていると仮定します。

var canvas:BitmapData = new BitmapData(600, 600, true, 0x0);
var bitmap:Bitmap = new Bitmap(canvas, PixelSnapping.AUTO, true);
addChild(bitmap);

この実装では、 をインスタンス化し、StarAssetに描画してBitmapDataから、キャンバスに描画されたコピーごとにスケール、位置、および回転をランダムに変換します。

makeStars();

function makeStars():void
{
    // get the star asset
    var s:StarAsset = new StarAsset();

    // copy star asset to bitmap data
    var bd:BitmapData = new BitmapData(s.width, s.height, true, 0x0);
    bd.draw(s);

    // draw 100 variants on BitmapData
    for(var i:uint = 0; i < 100; i++)
    {
        var positionX:Number = Math.random() * 600;
        var positionY:Number = Math.random() * 600;
        var scale:Number = Math.random();
        var angle:Number = Math.random() * 360;

        var matrix:Matrix = new Matrix();
        matrix.scale(scale, scale);
        matrix.rotate(angle * Math.PI / 180);
        matrix.translate(positionX, positionY);

        canvas.draw(bd, matrix, null, null, null, true);
    }
}

生成するもの:

出演者

または、ここでは 1,000 個の星が描かれています。

星-1000

または、最終的に 10,000 個の星が描画されます。

星-10000

于 2012-07-15T03:06:51.337 に答える