13

巨大なxslファイルがありますが、「トークン化」を使用してコンマ区切りの文字列を解析するセクションでエラーがスローされます。簡単にするために、トークン化された部分のみをテストするために分解しましたが、進歩は見られません。次のエラーが発生し続けます。

表現が期待されます。tokenize（-> [<-text]、'、'）

他の投稿で共有されているxslの例を使用してみましたが、うまく機能しませんでした。以下のxslコードが無効である理由を理解するのに苦労しています。とても簡単なことではないようですが、私は単純なものが欠けていると思います。私を正しい方向に導くための助けをいただければ幸いです。

XSL：

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/root">
<xsl:for-each select="tokenize([text],',')"/>
<items>
<item>
<xsl:value-of select="."/>
</item>
</items>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>

XML：

<?xml-stylesheet type="text/xsl" href="simple.xsl"?>
<root>
<text>Item1, Item2, Item3</text>
</root>

次のようなXML出力を期待しています。

<items>
<item>Item1</item>
<item>Item2</item>
<item>Item3</item>
</items>

ありがとうございました！

4

2 に答える 2

11

私は4つのことが間違っていると思います：

  1. tokenize()1.0 スタイルシートで使用しています。バージョンを 2.0 に変更し、2.0 プロセッサを使用する必要があります。処理命令に基づいて変換を行うために Web ブラウザを使用している場合、xml-stylesheetおそらく 2.0 プロセッサを使用していません。

  2. tokenize ( [text]) の最初の引数が無効です。を使用するだけtextです。

  3. を閉じるのが早すぎましたxsl:for-each。

  4. <items>for each item を出力しています。<items>の外側に置きxsl:for-eachます。

変更例:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/root">
        <items>
            <xsl:for-each select="tokenize(text,',')">
                <item>
                    <xsl:value-of select="."/>
                </item>
            </xsl:for-each>
        </items>
    </xsl:template>
</xsl:stylesheet>

2.0 プロセッサで目的の出力を本当に得るには、 and を使用することもお勧めしxsl:outputますnormalize-space()。

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>

    <xsl:template match="/root">
        <items>
            <xsl:for-each select="tokenize(text,',')">
                <item>
                    <xsl:value-of select="normalize-space(.)"/>
                </item>
            </xsl:for-each>
        </items>
    </xsl:template>

</xsl:stylesheet>
于 2012-07-14T23:10:41.343 に答える
5

DevNull が述べているように、tokenize() は XSLT 2.0 関数です。ただし、プロセッサが EXSLT をサポートしている場合は、 str:tokenize() 関数を使用できます。それ以外の場合は、次のようにコンマ区切りの値を分割するためにユーザー再帰が必要になります...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />

<xsl:template match="/">
 <items>
   <xsl:apply-templates select="root/text"/>
 </items>
</xsl:template>

<xsl:template match="text">
 <xsl:call-template name="tokenize"> 
   <xsl:with-param name="csv" select="." /> 
 </xsl:call-template>    
</xsl:template>

<xsl:template name="tokenize">
 <xsl:param name="csv" />
  <xsl:variable name="first-item" select="normalize-space( 
    substring-before( concat( $csv, ','), ','))" /> 
 <xsl:if test="$first-item">
  <item>
   <xsl:value-of select="$first-item" /> 
  </item>  
  <xsl:call-template name="tokenize"> 
   <xsl:with-param name="csv" select="substring-after($csv,',')" /> 
  </xsl:call-template>    
 </xsl:if>  
</xsl:template>

</xsl:stylesheet>
于 2012-07-15T15:21:28.883 に答える